From dabf1489915c1df22bde8d55f4f6262404611505 Mon Sep 17 00:00:00 2001
From: Stefan Strogin <stefan.strogin@gmail.com>
Date: Tue, 8 Jan 2019 15:09:10 +0200
Subject: media-sound/vimpc: add live ebuild

Package-Manager: Portage-2.3.54, Repoman-2.3.12
Signed-off-by: Stefan Strogin <stefan.strogin@gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/10776
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
---
 media-sound/vimpc/metadata.xml      |  2 +-
 media-sound/vimpc/vimpc-9999.ebuild | 42 +++++++++++++++++++++++++++++++++++++
 2 files changed, 43 insertions(+), 1 deletion(-)
 create mode 100644 media-sound/vimpc/vimpc-9999.ebuild

(limited to 'media-sound')

diff --git a/media-sound/vimpc/metadata.xml b/media-sound/vimpc/metadata.xml
index 936e40a0e753..ffbeaf1f8a30 100644
--- a/media-sound/vimpc/metadata.xml
+++ b/media-sound/vimpc/metadata.xml
@@ -9,6 +9,6 @@
 		<flag name="boost">Use boost instead of C++11 libraries</flag>
 	</use>
 	<upstream>
-		<remote-id type="sourceforge">vimpc</remote-id>
+		<remote-id type="github">boysetsfrog/vimpc</remote-id>
 	</upstream>
 </pkgmetadata>
diff --git a/media-sound/vimpc/vimpc-9999.ebuild b/media-sound/vimpc/vimpc-9999.ebuild
new file mode 100644
index 000000000000..c019bc106184
--- /dev/null
+++ b/media-sound/vimpc/vimpc-9999.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools git-r3
+
+DESCRIPTION="An ncurses based mpd client with vi like key bindings"
+HOMEPAGE="https://github.com/boysetsfrog/vimpc"
+EGIT_REPO_URI="https://github.com/boysetsfrog/${PN}.git"
+
+LICENSE="GPL-3"
+SLOT="0"
+IUSE="boost taglib"
+
+RDEPEND="dev-libs/libpcre
+	media-libs/libmpdclient
+	boost? ( dev-libs/boost:= )
+	taglib? ( media-libs/taglib )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( AUTHORS README.md doc/vimpcrc.example )
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable boost) \
+		$(use_enable taglib) \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF}
+}
+
+src_install() {
+	default
+
+	# vimpc will look for help.txt
+	docompress -x /usr/share/doc/${PF}/help.txt
+}
-- 
cgit v1.2.3-65-gdbad