From 5c49d49786ea2680f3e9298a4df10b0844a767f5 Mon Sep 17 00:00:00 2001
From: Michał Górny <mgorny@gentoo.org>
Date: Wed, 9 Aug 2023 05:03:29 +0200
Subject: dev-python/pdm-backend: Bump to 2.1.5
MIME-Version: 1.0
Content-Type: text/plain; charset=UTF-8
Content-Transfer-Encoding: 8bit

Signed-off-by: Michał Górny <mgorny@gentoo.org>
---
 dev-python/pdm-backend/Manifest                 |  1 +
 dev-python/pdm-backend/pdm-backend-2.1.5.ebuild | 68 +++++++++++++++++++++++++
 2 files changed, 69 insertions(+)
 create mode 100644 dev-python/pdm-backend/pdm-backend-2.1.5.ebuild

(limited to 'dev-python/pdm-backend')

diff --git a/dev-python/pdm-backend/Manifest b/dev-python/pdm-backend/Manifest
index 967ddd1cf175..c589010af7c2 100644
--- a/dev-python/pdm-backend/Manifest
+++ b/dev-python/pdm-backend/Manifest
@@ -1 +1,2 @@
 DIST pdm-backend-2.1.4.gh.tar.gz 134278 BLAKE2B 38e52761d54cab96727d5015e41de76cd6d7eb6dbd02829ed2ddeeb2e2d64d42a0eb6bb09e055362e1dd181d9e7781ed9f9abcb2f96de342cd5780e1f21a8708 SHA512 4833819f8828f5e2ff204ca18478704d8d66c977c747f9b550dc1ecfee57a8adbfcddaea6dded8d8ea0c0e0c7745e0704e12acae30d183cb27cf4c1fad331791
+DIST pdm-backend-2.1.5.gh.tar.gz 134316 BLAKE2B 9337990b4ed009e506f0eee82e9f8d50fc281dbf917dc964daf75230a4c2b9cc5bf0748afe9aa7b5b6f9036249b87ec338b129136b2fd92619c12000e77a7663 SHA512 867c36a9381f4e6a2c81f2d987ce33953eaf78a43b4fa03df54f78b6c9cfe645a1ae4f3dd1a514e0d14208ad7fc75af954fa46be3c8b4b54c7ac7e16eead5aaf
diff --git a/dev-python/pdm-backend/pdm-backend-2.1.5.ebuild b/dev-python/pdm-backend/pdm-backend-2.1.5.ebuild
new file mode 100644
index 000000000000..2e31060b91df
--- /dev/null
+++ b/dev-python/pdm-backend/pdm-backend-2.1.5.ebuild
@@ -0,0 +1,68 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=standalone
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1
+
+DESCRIPTION="A PEP 517 backend for PDM that supports PEP 621 metadata"
+HOMEPAGE="
+	https://pypi.org/project/pdm-backend/
+	https://github.com/pdm-project/pdm-backend/
+"
+SRC_URI="
+	https://github.com/pdm-project/pdm-backend/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	>=dev-python/packaging-22.0[${PYTHON_USEDEP}]
+	>=dev-python/pyproject-metadata-0.7.1[${PYTHON_USEDEP}]
+	>=dev-python/tomli-w-1.0.0[${PYTHON_USEDEP}]
+
+	$(python_gen_cond_dep '
+		>=dev-python/tomli-2.0.1[${PYTHON_USEDEP}]
+	' 3.10)
+"
+BDEPEND="
+	${RDEPEND}
+	test? (
+		dev-python/setuptools[${PYTHON_USEDEP}]
+		dev-vcs/git
+	)
+"
+# setuptools are used to build C extensions
+RDEPEND+="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	rm -r src/pdm/backend/_vendor || die
+	find -name '*.py' -exec sed \
+		-e 's:from pdm\.backend\._vendor\.:from :' \
+		-e 's:from pdm\.backend\._vendor ::' \
+		-e 's:import pdm\.backend\._vendor\.:import :' \
+		-i {} + || die
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	# this must not be set during src_test()
+	local -x PDM_BUILD_SCM_VERSION=${PV}
+	distutils-r1_src_compile
+}
+
+src_test() {
+	git config --global user.email "test@example.com" || die
+	git config --global user.name "Test User" || die
+	distutils-r1_src_test
+}
-- 
cgit v1.2.3-65-gdbad