From 2fec2a9762b893d6e497445c4f79df26e438735e Mon Sep 17 00:00:00 2001
From: Sam James <sam@gentoo.org>
Date: Wed, 19 May 2021 03:17:56 +0000
Subject: dev-libs/cdk: drop libtool

In some cases, configure seems to be producing a Makefile with a broken
install target (which lacks the needed libtool install finalisation). Let's
just disable libtool for now, we don't need it.

Closes: https://bugs.gentoo.org/790773
Signed-off-by: Sam James <sam@gentoo.org>
---
 dev-libs/cdk/cdk-5.0.20210324-r1.ebuild | 54 +++++++++++++++++++++++++++++++++
 dev-libs/cdk/cdk-5.0.20210324.ebuild    | 53 --------------------------------
 2 files changed, 54 insertions(+), 53 deletions(-)
 create mode 100644 dev-libs/cdk/cdk-5.0.20210324-r1.ebuild
 delete mode 100644 dev-libs/cdk/cdk-5.0.20210324.ebuild

(limited to 'dev-libs/cdk')

diff --git a/dev-libs/cdk/cdk-5.0.20210324-r1.ebuild b/dev-libs/cdk/cdk-5.0.20210324-r1.ebuild
new file mode 100644
index 000000000000..6aee2fbce644
--- /dev/null
+++ b/dev-libs/cdk/cdk-5.0.20210324-r1.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${PN}-$(ver_rs 2 -)"
+
+DESCRIPTION="A library of curses widgets"
+HOMEPAGE="https://dickey.his.com/cdk/cdk.html"
+SRC_URI="ftp://ftp.invisible-island.net/cdk/${MY_P}.tgz"
+S="${WORKDIR}"/${MY_P}
+
+LICENSE="BSD"
+SLOT="0/6" # subslot = soname version
+KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="examples unicode"
+
+DEPEND=">=sys-libs/ncurses-5.2:0=[unicode?]"
+RDEPEND="${DEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=( "${FILESDIR}"/${PN}-5.0.20120323-parallel-make.patch )
+
+src_configure() {
+	if [[ ${CHOST} == *-*-darwin* ]] ; then
+		export ac_cv_prog_LIBTOOL=glibtool
+	fi
+
+	# --with-libtool dropped for now because of broken Makefile
+	# bug #790773
+	econf \
+		--disable-rpath-hack \
+		--with-shared \
+		--with-pkg-config \
+		--with-ncurses$(usex unicode "w" "")
+}
+
+src_install() {
+	# parallel make installs duplicate libs
+	emake -j1 \
+		DESTDIR="${D}" \
+		DOCUMENT_DIR="${ED}/usr/share/doc/${PF}" \
+		install
+
+	if use examples ; then
+		local x
+		for x in include c++ demos examples cli cli/utils cli/samples ; do
+			docinto ${x}
+			find ${x} -maxdepth 1 -mindepth 1 -type f -print0 | xargs -0 dodoc || die
+		done
+	fi
+
+	find "${ED}" \( -name '*.a' -or -name '*.la' \) -delete || die
+}
diff --git a/dev-libs/cdk/cdk-5.0.20210324.ebuild b/dev-libs/cdk/cdk-5.0.20210324.ebuild
deleted file mode 100644
index 30eddf517e27..000000000000
--- a/dev-libs/cdk/cdk-5.0.20210324.ebuild
+++ /dev/null
@@ -1,53 +0,0 @@
-# Copyright 1999-2021 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-MY_P="${PN}-$(ver_rs 2 -)"
-
-DESCRIPTION="A library of curses widgets"
-HOMEPAGE="https://dickey.his.com/cdk/cdk.html"
-SRC_URI="ftp://ftp.invisible-island.net/cdk/${MY_P}.tgz"
-S="${WORKDIR}"/${MY_P}
-
-LICENSE="BSD"
-SLOT="0/6" # subslot = soname version
-KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
-IUSE="examples unicode"
-
-DEPEND=">=sys-libs/ncurses-5.2:0=[unicode?]"
-RDEPEND="${DEPEND}"
-BDEPEND="sys-devel/libtool
-	virtual/pkgconfig"
-
-PATCHES=( "${FILESDIR}"/${PN}-5.0.20120323-parallel-make.patch )
-
-src_configure() {
-	if [[ ${CHOST} == *-*-darwin* ]] ; then
-		export ac_cv_prog_LIBTOOL=glibtool
-	fi
-
-	econf \
-		--disable-rpath-hack \
-		--with-libtool \
-		--with-shared \
-		--with-pkg-config \
-		--with-ncurses$(usex unicode "w" "")
-}
-
-src_install() {
-	# parallel make installs duplicate libs
-	emake -j1 \
-		DESTDIR="${D}" \
-		DOCUMENT_DIR="${ED}/usr/share/doc/${PF}" install
-
-	if use examples ; then
-		local x
-		for x in include c++ demos examples cli cli/utils cli/samples ; do
-			docinto ${x}
-			find ${x} -maxdepth 1 -mindepth 1 -type f -print0 | xargs -0 dodoc || die
-		done
-	fi
-
-	find "${ED}" \( -name '*.a' -or -name '*.la' \) -delete || die
-}
-- 
cgit v1.2.3-65-gdbad