From 8eb8edc7566fcab7b19f136338c06f6bd0f5b64e Mon Sep 17 00:00:00 2001
From: Gilles Dartiguelongue <eva@gentoo.org>
Date: Fri, 30 Sep 2016 23:44:25 +0200
Subject: app-text/rarian: unbundle tinyxml, apply patches from other distros

Project is most certainly dead nowadays but a surprising number of
patches from Redhat, Debian and Ubuntu are lying around waiting to be
collected. Since unbundling tinyxml produced a patch too big for
repoman to accept, these are provided via a tarball in dev space.

Bump ebuild to EAPI6.

Gentoo-bug: 252920

Package-Manager: portage-2.3.1
---
 app-text/rarian/Manifest               |  1 +
 app-text/rarian/rarian-0.8.1-r3.ebuild | 66 ++++++++++++++++++++++++++++++++++
 2 files changed, 67 insertions(+)
 create mode 100644 app-text/rarian/rarian-0.8.1-r3.ebuild

(limited to 'app-text/rarian')

diff --git a/app-text/rarian/Manifest b/app-text/rarian/Manifest
index b54bb63b7cda..a62f57439e79 100644
--- a/app-text/rarian/Manifest
+++ b/app-text/rarian/Manifest
@@ -1 +1,2 @@
+DIST rarian-0.8.1-r3-patches.tar.xz 33508 SHA256 204f4f57724bc4c6f914df5cecea0b799b0f0f166f12e6462ea3762c76c6f234 SHA512 a6a258803ce165854047aacd1ffef32d8d5c271cad3e6b74fb3c694ca6a0de9a8f253c89f9ff53279e7228ae401fad06721f10a6374a03a51bad76b2ef969000 WHIRLPOOL 1824c7e537e9d10e126e3bf8b0b6ed388394ac47b29ea5c5cb4685557572b9a61c663a0337fea34f982782e625c559f549b371934b2f125b4eec1cbf4ee258ad
 DIST rarian-0.8.1.tar.gz 459461 SHA256 b410d9581dddfabe93e29f9e235a9f9d04d33d8eb12afd0f5ad3bd238c55adef SHA512 ddc640e1ac210e9dc3fcdde6bbff6e21dabe97b160b531cac68d47d1b831dec71b7c4aced9819cfafd8f89f290920c4e33550b8e29d9872a1c1a202d6fe8e3eb WHIRLPOOL bd11206a4701e1771ebd5d82123d299c1c3cbb7ecfa6e00654372494d07b8f47cdfc6e88dc8ea6a405acdae0f57b12ae8c927a952f42d55cdab8f1214f0ac237
diff --git a/app-text/rarian/rarian-0.8.1-r3.ebuild b/app-text/rarian/rarian-0.8.1-r3.ebuild
new file mode 100644
index 000000000000..ae24e00ecdf8
--- /dev/null
+++ b/app-text/rarian/rarian-0.8.1-r3.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit autotools eutils
+
+DESCRIPTION="A documentation metadata library"
+HOMEPAGE="https://rarian.freedesktop.org/"
+SRC_URI="https://${PN}.freedesktop.org/Releases/${P}.tar.gz
+	https://dev.gentoo.org/~eva/distfiles/${PN}/${P}-r3-patches.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x86-freebsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x64-solaris ~x86-solaris"
+IUSE="static-libs"
+
+RDEPEND="
+	dev-libs/libxslt
+	dev-libs/tinyxml
+	|| (
+		sys-apps/util-linux
+		app-misc/getopt )
+"
+DEPEND="${RDEPEND}
+	!<app-text/scrollkeeper-9999
+"
+
+DOCS=( ChangeLog NEWS README )
+
+PATCHES=(
+	"${WORKDIR}"/0001-Fix-uri-of-omf-files-produced-by-rarian-sk-preinstal.patch
+	"${WORKDIR}"/0002-Allow-building-against-system-copy-of-tinyxml.patch
+	"${WORKDIR}"/0003-Allow-to-specify-only-the-prefix-of-an-info-page-e.g.patch
+	"${WORKDIR}"/0004-Fix-a-crash-when-opening-files-without-dots-in-their.patch
+	"${WORKDIR}"/0005-Make-librarian-obey-to-LC_MESSAGES.patch
+	"${WORKDIR}"/0006-Fix-m4-syntax-so-that-autoreconf-doesn-t-break.patch
+	"${WORKDIR}"/0007-Remove-the-nonexistent-dist-gzip-Automake-option.patch
+	"${WORKDIR}"/0008-Fix-OMF-category-parsing.patch
+	"${WORKDIR}"/0009-Allow-the-getopt-command-to-be-customized-at-configu.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=()
+	# https://bugs.gentoo.org/show_bug.cgi?id=409811
+	# https://bugs.freedesktop.org/show_bug.cgi?id=53264
+	if ! has_version sys-apps/util-linux; then
+		myconf=( --with-getopt=getopt-long )
+	fi
+
+	econf \
+		--localstatedir="${EPREFIX}"/var \
+		$(use_enable static-libs static) \
+		${myconf[@]}
+}
+
+src_install() {
+	default
+	prune_libtool_files --all
+}
-- 
cgit v1.2.3-65-gdbad