1 files changed, 60 insertions, 0 deletions
diff --git a/media-sound/lame/lame-3.99.3.ebuild b/media-sound/lame/lame-3.99.3.ebuild
new file mode 100644
index 000000000000..ed3625a28b71
--- /dev/null
+++ b/media-sound/lame/lame-3.99.3.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=4
+inherit autotools eutils
+
+DESCRIPTION="LAME Ain't an MP3 Encoder"
+HOMEPAGE="http://lame.sourceforge.net/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="alpha amd64 arm hppa ia64 ~mips ppc ppc64 sh sparc x86 ~x86-fbsd ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug cpu_flags_x86_mmx mp3rtp sndfile static-libs"
+
+RDEPEND=">=sys-libs/ncurses-5.2
+	sndfile? ( >=media-libs/libsndfile-1.0.2 )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	cpu_flags_x86_mmx? ( dev-lang/nasm )"
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${PN}-3.96-ccc.patch \
+		"${FILESDIR}"/${PN}-3.98-gtk-path.patch
+
+	mkdir libmp3lame/i386/.libs || die #workaround parallel build with nasm
+
+	sed -i -e '/define sp/s/+/ + /g' libmp3lame/i386/nasm.h || die
+
+	use cpu_flags_x86_mmx || sed -i -e '/AC_PATH_PROG/s:nasm:dIsAbLe&:' configure.in #361879
+
+	AT_M4DIR=${S} eautoreconf
+	epunt_cxx #74498
+}
+
+src_configure() {
+	local myconf
+	use cpu_flags_x86_mmx && myconf+="--enable-nasm" #361879
+	use sndfile && myconf+=" --with-fileio=sndfile"
+
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable debug debug norm) \
+		--disable-mp3x \
+		$(use_enable mp3rtp) \
+		--enable-dynamic-frontends \
+		${myconf}
+}
+
+src_install() {
+	emake DESTDIR="${D}" pkghtmldir="${EPREFIX}/usr/share/doc/${PF}/html" install
+	dobin misc/mlame
+
+	dodoc API ChangeLog HACKING README STYLEGUIDE TODO USAGE
+	dohtml misc/lameGUI.html Dll/LameDLLInterface.htm
+
+	find "${ED}" -name '*.la' -exec rm -f {} +
+}