1 files changed, 71 insertions, 0 deletions
diff --git a/dev-libs/Imath/Imath-3.1.7.ebuild b/dev-libs/Imath/Imath-3.1.7.ebuild
new file mode 100644
index 000000000000..6bf1de90a8d2
--- /dev/null
+++ b/dev-libs/Imath/Imath-3.1.7.ebuild
@@ -0,0 +1,71 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+
+inherit cmake python-single-r1
+
+DESCRIPTION="Imath basic math package"
+HOMEPAGE="https://imath.readthedocs.io"
+SRC_URI="https://github.com/AcademySoftwareFoundation/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+# re-keywording needed for (according to ilmbase keywords): ~x64-macos
+KEYWORDS="amd64 ~arm arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
+
+LICENSE="BSD"
+SLOT="3/30"
+IUSE="large-stack python test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+RESTRICT="!test? ( test )"
+
+# blocker due to file collision #803347
+RDEPEND="
+	!dev-libs/imath:0
+	!media-libs/ilmbase
+	sys-libs/zlib
+	python? (
+		!dev-python/pyilmbase
+		${PYTHON_DEPS}
+		$(python_gen_cond_dep '
+			dev-libs/boost:=[python,${PYTHON_USEDEP}]
+			dev-python/numpy[${PYTHON_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	python? ( ${PYTHON_DEPS} )
+"
+
+DOCS=( CHANGES.md CONTRIBUTORS.md README.md SECURITY.md docs/PortingGuide2-3.md )
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		# requires press theme, not available in ::gentoo
+		-DBUILD_DOCS=OFF
+		-DIMATH_ENABLE_LARGE_STACK=$(usex large-stack)
+		# the following options are at their default value
+		-DIMATH_HALF_USE_LOOKUP_TABLE=ON
+		-DIMATH_INSTALL_PKG_CONFIG=ON
+		-DIMATH_USE_CLANG_TIDY=OFF
+		-DIMATH_USE_DEFAULT_VISIBILITY=OFF
+		-DIMATH_USE_NOEXCEPT=ON
+	)
+	if use python; then
+		mycmakeargs+=(
+			-DBoost_NO_BOOST_CMAKE=OFF
+			-DPYTHON=ON
+			-DPython3_EXECUTABLE="${PYTHON}"
+			-DPython3_INCLUDE_DIR=$(python_get_includedir)
+			-DPython3_LIBRARY=$(python_get_library_path)
+		)
+	fi
+
+	cmake_src_configure
+}