2 files changed, 77 insertions, 0 deletions
diff --git a/dev-db/mycli/Manifest b/dev-db/mycli/Manifest
index de5904294910..cf298dd7c563 100644
--- a/dev-db/mycli/Manifest
+++ b/dev-db/mycli/Manifest
@@ -1 +1,2 @@
 DIST mycli-1.27.0.gh.tar.gz 285739 BLAKE2B 9b3ba8b98289721774d7bf06465402440d70772ee4f456f1a14a02a0f0cf90e6c4e6fe2abe36436ea051042bed208868dc469e9ef7c4499a9fdacd519b119199 SHA512 ae6fa9ed9151a39988ea64c5d551a68c92014cbaae4ec6695a727cd008882298d3373d1992768eff0781e881738f72f00dfe4756196c0ba82009758b1ea16b51
+DIST mycli-1.27.2.gh.tar.gz 286537 BLAKE2B 7bff978f9a08561c33f5327f13b8b69226e5c735527a607190a3c5d75f091b9f76b8d432e7a3e315ff250995e0baea7f7e0bede17e0b1cc6654939b7ec82b0ae SHA512 fdf0342b0e850b5232c815e73f44f22c7ea162201588681ccf2f4107b84b87f01fff3999a9720fef454239192356f074f47642ddc760af18973a2aaaac4676cd
diff --git a/dev-db/mycli/mycli-1.27.2.ebuild b/dev-db/mycli/mycli-1.27.2.ebuild
new file mode 100644
index 000000000000..445b7b84997e
--- /dev/null
+++ b/dev-db/mycli/mycli-1.27.2.ebuild
@@ -0,0 +1,76 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_SINGLE_IMPL=yes
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..12} )
+
+inherit distutils-r1
+
+DESCRIPTION="CLI for MySQL Database with auto-completion and syntax highlighting"
+HOMEPAGE="
+	https://www.mycli.net/
+	https://github.com/dbcli/mycli/
+	https://pypi.org/project/mycli/
+"
+SRC_URI="
+	https://github.com/dbcli/mycli/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="ssh"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		>=dev-python/cli-helpers-2.2.1[${PYTHON_USEDEP}]
+		>=dev-python/click-7.0[${PYTHON_USEDEP}]
+		>=dev-python/configobj-5.0.5[${PYTHON_USEDEP}]
+		>=dev-python/cryptography-1.0.0[${PYTHON_USEDEP}]
+		>=dev-python/prompt-toolkit-3.0.6[${PYTHON_USEDEP}]
+		<dev-python/prompt-toolkit-4.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pyaes-1.6.1[${PYTHON_USEDEP}]
+		>=dev-python/pygments-1.6[${PYTHON_USEDEP}]
+		>=dev-python/pymysql-0.9.2[${PYTHON_USEDEP}]
+		>=dev-python/pyperclip-1.8.1[${PYTHON_USEDEP}]
+		>=dev-python/sqlglot-5.1.3[${PYTHON_USEDEP}]
+		>=dev-python/sqlparse-0.3.0[${PYTHON_USEDEP}]
+		ssh? ( dev-python/paramiko[${PYTHON_USEDEP}] )
+	')
+"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/paramiko[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+EPYTEST_DESELECT=(
+	# Requires a running mysql daemon
+	"test/test_main.py::test_batch"
+	"test/test_main.py::test_execute"
+	"test/test_main.py::test_init"
+	"test/test_special_iocommands.py::test_favorite_query"
+	"test/test_special_iocommands.py::test_watch"
+	"test/test_tabular_output.py::test_sql_output"
+)
+
+EPYTEST_IGNORE=(
+	# Requires a running mysql daemon
+	"test/test_sqlexecute.py"
+)
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	# Relax sqlparse requirement, 0.5.0 didn't have major API changes that would necessitate this restriction.
+	# bug #930690
+	sed -i -e '/sqlparse/ s/,<0.5.0//' setup.py || die
+}