1 files changed, 46 insertions, 0 deletions
diff --git a/app-text/docbook-sgml-dtd/docbook-sgml-dtd-4.5-r2.ebuild b/app-text/docbook-sgml-dtd/docbook-sgml-dtd-4.5-r2.ebuild
new file mode 100644
index 000000000000..2b8e3af280e1
--- /dev/null
+++ b/app-text/docbook-sgml-dtd/docbook-sgml-dtd-4.5-r2.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit sgml-catalog-r1
+
+MY_P="docbook-${PV}"
+DESCRIPTION="Docbook SGML DTD ${PV}"
+HOMEPAGE="https://docbook.org/sgml/"
+SRC_URI="https://docbook.org/sgml/${PV}/${MY_P}.zip"
+
+LICENSE="docbook"
+SLOT="${PV}"
+KEYWORDS="~alpha amd64 arm arm64 hppa ~ia64 ~m68k ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
+IUSE=""
+
+BDEPEND=">=app-arch/unzip-5.41"
+
+S="${WORKDIR}"
+PATCHES=( "${FILESDIR}"/${P}-catalog.diff )
+
+src_install() {
+	insinto /usr/share/sgml/docbook/sgml-dtd-${PV}
+	doins *.dcl *.dtd *.mod *.xml
+	newins docbook.cat catalog
+	insinto /etc/sgml
+	newins - sgml-docbook-${PV}.cat <<-EOF
+		CATALOG "${EPREFIX}/usr/share/sgml/docbook/sgml-dtd-${PV}/catalog"
+		CATALOG "${EPREFIX}/etc/sgml/sgml-docbook.cat"
+	EOF
+	dodoc README
+}
+
+pkg_preinst() {
+	# work-around -r0 postrm removing it
+	cp "${ED}"/etc/sgml/sgml-docbook-${PV}.cat "${T}" || die
+}
+
+pkg_postinst() {
+	local backup=${T}/sgml-docbook-${PV}.cat
+	local real=${EROOT}/etc/sgml/sgml-docbook-${PV}.cat
+	if ! cmp -s "${backup}" "${real}"; then
+		cp "${backup}" "${real}" || die
+	fi
+	sgml-catalog-r1_pkg_postinst
+}