1 files changed, 65 insertions, 0 deletions
diff --git a/app-backup/borgmatic/borgmatic-1.6.5.ebuild b/app-backup/borgmatic/borgmatic-1.6.5.ebuild
new file mode 100644
index 000000000000..502919f25ae7
--- /dev/null
+++ b/app-backup/borgmatic/borgmatic-1.6.5.ebuild
@@ -0,0 +1,65 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{8..11} )
+DISTUTILS_SINGLE_IMPL=1
+DISTUTILS_USE_PEP517=setuptools
+
+inherit distutils-r1 systemd
+
+DESCRIPTION="Automatically create, prune and verify backups with borgbackup"
+HOMEPAGE="https://torsion.org/borgmatic/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~riscv"
+
+# borg is called as an external tool, hence no pythonic stuff
+RDEPEND="app-backup/borgbackup
+	$(python_gen_cond_dep '
+		<dev-python/colorama-0.5[${PYTHON_USEDEP}]
+		dev-python/jsonschema[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		<dev-python/ruamel-yaml-0.18.0[${PYTHON_USEDEP}]
+		dev-python/setuptools[${PYTHON_USEDEP}]
+	')"
+BDEPEND="
+	test? (
+		$(python_gen_cond_dep '
+			>=dev-python/flexmock-0.10.10[${PYTHON_USEDEP}]
+		')
+	)"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.5.1-no_test_coverage.patch
+	"${FILESDIR}"/${PN}-1.5.16-systemd_service_bin_path.patch
+)
+
+# test_borgmatic_version_matches_news_version tries to run the 'borgmatic'
+# executable so making it work would require passing --install
+# to distutils_enable_tests. Given that this is the only test requiring
+# this and that all it does is make sure the NEWS file has been updated
+# for the current version, just skip it.
+EPYTEST_DESELECT=(
+	tests/integration/commands/test_borgmatic.py::test_borgmatic_version_matches_news_version
+)
+
+distutils_enable_tests pytest
+
+src_install() {
+	distutils-r1_src_install
+	systemd_dounit sample/systemd/borgmatic.{service,timer}
+	keepdir /etc/borgmatic
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		elog "To generate a sample configuration file, run:"
+		elog "    generate-borgmatic-config"
+	fi
+	elog
+	elog "Systemd users wishing to periodically run borgmatic can use the provided timer and service units."
+}