1 files changed, 43 insertions, 0 deletions
diff --git a/app-arch/gnome-autoar/gnome-autoar-0.3.1.ebuild b/app-arch/gnome-autoar/gnome-autoar-0.3.1.ebuild
new file mode 100644
index 000000000000..5ef87130fe55
--- /dev/null
+++ b/app-arch/gnome-autoar/gnome-autoar-0.3.1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 vala
+
+DESCRIPTION="Automatic archives creating and extracting library"
+HOMEPAGE="https://git.gnome.org/browse/gnome-autoar"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+RDEPEND="
+	>=app-arch/libarchive-3.4.0
+	>=dev-libs/glib-2.35.6:2
+	gtk? ( >=x11-libs/gtk+-3.2:3[introspection?] )
+	introspection? ( >=dev-libs/gobject-introspection-1.30.0:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-util/gtk-doc-am-1.14
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--disable-static \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(use_enable gtk)
+}