www-client/opera-beta: automated bump (95.0.4635.10)

Signed-off-by: Stephan Hartmann <sultan@gentoo.org>

2 files changed, 167 insertions, 0 deletions

diff --git a/www-client/opera-beta/Manifest b/www-client/opera-beta/Manifest
index 9353eeb33b75..1a9f8ee58ce0 100644
--- a/www-client/opera-beta/Manifest
+++ b/www-client/opera-beta/Manifest
@@ -1,4 +1,6 @@
 DIST opera-beta_94.0.4606.14_amd64.deb 101475380 BLAKE2B 94a0eb0bf2c6018ec0d5e8a0eccd9c9ea494e88d0f50a200abe0d88855c697dedf4afe2da468208cb02fcfe5e028ff72debd0f54dcba9da4ada02fb4736b2fe8 SHA512 df4a67ff07b8b648035e299bafa30f7bcb5d428fa0473f4974d5b68825d8624f76d2041b87abec91269251ae1f683a6e2e0af17715d50d23e453616e03b574b7
 DIST opera-beta_94.0.4606.19_amd64.deb 101489260 BLAKE2B b1e083a85288417dcdeb552149471b5b1a7610f57ef7bed5f2f40333def96d03d024765f6aea070f14a4a0dcce5777b55f5bbda4f4c99b6ed8bcfa5227fca5f6 SHA512 4d400468103526ecb392ff7d55c18085c61913dcf2d77aa0a73c87965a7767ae7a640c06b14536be049768f32b167f427965b647af37d18e223b0b1133c711d5
 DIST opera-beta_94.0.4606.8_amd64.deb 101477468 BLAKE2B 63a5ae7c979df38332d29201bc765772a628aaa39f70205b52c6be03276d2b29d49c27f2b2be7da2a8a6d1a18448d9e932f569f5a5e902e5eea346357374b71e SHA512 bd65eac34f5b75450790ec6081a7589a05dd33b0934c518aed61508519133e54e824b22ea0e645a4ea0e451580cec2ce9d0f28ec46f68185a4d8efebe00e0e46
+DIST opera-beta_95.0.4635.10_amd64.deb 101350684 BLAKE2B eb4d2193be0f8e9313adcfde78700213c5bdc0daa9d58fd338b2c1a6657ec2f0a4aef119b008741edbe66f7c560d0008d9d5bb1a12ccd0331b8195fa3a6e7700 SHA512 f3eca403b34f7cfb2b126bd2345b8a8df21d76eb2b3c5a0ab6d5b65ccce22bc76e741c80fc1bad7c1147d4cef5a48b7b1376f4c8f4c0e1daad76c6a6566b7504
 DIST opera-ffmpeg-codecs-108.0.5359.125.tar.xz 1416300 BLAKE2B 9b4d3de10ae8c5efdf52a680829d1c7587dc23b79e39b1c456d8b747c56176b92952be792bc7fb1214c790bc571522630f83d66119a53e94ddb555b571bf1a35 SHA512 55eb35d5e9a1d859ec88cd87a03129e7ac12db7fd58480a0bd864903879529c15aa2f325bd495bad49029fa991824e3475c3f6b94b92a2896329a73261583452
+DIST opera-ffmpeg-codecs-110.0.5464.2.tar.xz 1280752 BLAKE2B 9f17f85377d06c7c36729ca3a29d02aa2d7fff3bbbeb4cc26f60252e350c50c3a06eeb7e3c896154617ff7ee43d5881177b819618c13dc1254f7d3980bf0c363 SHA512 d9b4a52b29be287e5d20f6922c64e0e3cbfcd7eedd3109c12ff72c376ab14bce4c421be4dccea2ed1e4c899f11dcc8416545911ca84d8d6c994fe6ab87425ff3
diff --git a/www-client/opera-beta/opera-beta-95.0.4635.10.ebuild b/www-client/opera-beta/opera-beta-95.0.4635.10.ebuild
new file mode 100644
index 000000000000..c1bd86836a82
--- /dev/null
+++ b/www-client/opera-beta/opera-beta-95.0.4635.10.ebuild
@@ -0,0 +1,165 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+CHROMIUM_LANGS="
+	bg bn ca cs da de el en-GB en-US es-419 es fil fi fr hi hr hu id
+	it ja ko lt lv ms nb nl pl pt-BR pt-PT ro ru sk sr sv sw ta te th tr uk vi
+	zh-CN zh-TW
+"
+
+# These are intended for ebuild maintainer use to force RPM if DEB is not available.
+: ${OPERA_FORCE_RPM=no}
+
+inherit chromium-2 pax-utils xdg
+
+if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+	inherit rpm
+	OPERA_ARCHIVE_EXT="rpm"
+else
+	inherit unpacker
+	OPERA_ARCHIVE_EXT="deb"
+fi
+
+DESCRIPTION="A fast and secure web browser"
+HOMEPAGE="https://www.opera.com/"
+LICENSE="OPERA-2018"
+SLOT="0"
+
+SRC_URI_BASE=(
+	"https://download1.operacdn.com/pub/${PN}"
+	"https://download2.operacdn.com/pub/${PN}"
+	"https://download3.operacdn.com/pub/${PN}"
+	"https://download4.operacdn.com/pub/${PN}"
+)
+
+if [[ ${PN} == opera ]]; then
+	MY_PN=${PN}-stable
+	SRC_URI_BASE=( "${SRC_URI_BASE[@]/%//desktop}" )
+else
+	MY_PN=${PN}
+fi
+
+KEYWORDS="-* ~amd64"
+
+FFMPEG_VERSION="110.0.5464.2"
+
+SRC_URI="${SRC_URI_BASE[@]/%//${PV}/linux/${MY_PN}_${PV}_amd64.${OPERA_ARCHIVE_EXT}}
+	proprietary-codecs? (
+		mirror+https://dev.gentoo.org/~sultan/distfiles/www-client/opera/opera-ffmpeg-codecs-${FFMPEG_VERSION}.tar.xz
+	)"
+
+IUSE="+proprietary-codecs +suid qt5"
+RESTRICT="bindist mirror strip"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nspr
+	dev-libs/nss
+	gnome-base/gsettings-desktop-schemas
+	media-libs/alsa-lib
+	media-libs/mesa[gbm(+)]
+	net-misc/curl
+	net-print/cups
+	sys-apps/dbus
+	sys-libs/glibc
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf
+	x11-libs/gtk+:3
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/libxshmfence
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/pango
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5[X]
+		dev-qt/qtwidgets:5
+	)
+"
+
+QA_PREBUILT="*"
+S=${WORKDIR}
+OPERA_HOME="opt/opera${PN#opera}"
+
+pkg_pretend() {
+	# Protect against people using autounmask overzealously
+	use amd64 || die "opera only works on amd64"
+}
+
+pkg_setup() {
+	chromium_suid_sandbox_check_kernel_config
+}
+
+src_unpack() {
+	:
+}
+
+src_install() {
+	dodir /
+	cd "${ED}" || die
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rpm_src_unpack "${A[0]}"
+	else
+		unpacker
+	fi
+
+	# move to /opt, bug #573052
+	mkdir -p "${OPERA_HOME%${PN}}"
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		mv "usr/lib64/${PN}" "${OPERA_HOME%${PN}}" || die
+	else
+		mv "usr/lib/x86_64-linux-gnu/${PN}" "${OPERA_HOME%${PN}}" || die
+	fi
+	rm -r "usr/lib" || die
+
+	# disable auto update
+	rm "${OPERA_HOME}/${PN%-*}_autoupdate"{,.licenses,.version} || die
+
+	if [[ ${OPERA_FORCE_RPM} == yes ]]; then
+		rm "${OPERA_HOME}/setup_repo.sh" || die
+	else
+		rm -r "usr/share/lintian" || die
+
+		# fix docs
+		mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+		gzip -d usr/share/doc/${PF}/changelog.gz || die
+	fi
+
+	# fix desktop file
+	sed -i \
+		-e 's|^TargetEnvironment|X-&|g' \
+		usr/share/applications/${PN}.desktop || die
+
+	# remove unused language packs
+	pushd "${OPERA_HOME}/localization" > /dev/null || die
+	chromium_remove_language_paks
+	popd > /dev/null || die
+
+	# setup opera symlink
+	rm "usr/bin/${PN}" || die
+	dosym "../../${OPERA_HOME}/${PN}" "/usr/bin/${PN}"
+
+	# install proprietary codecs
+	rm "${OPERA_HOME}/resources/ffmpeg_preload_config.json" || die
+	if use proprietary-codecs; then
+		mv lib_extra "${OPERA_HOME}"
+	fi
+
+	if ! use qt5; then
+		rm "${OPERA_HOME}/libqt5_shim.so" || die
+	fi
+
+	# pax mark opera, bug #562038
+	pax-mark m "${OPERA_HOME}/opera"
+	# enable suid sandbox if requested
+	use suid && fperms 4711 "/${OPERA_HOME}/opera_sandbox"
+}