media-plugins/grilo-plugins: Bump to 0.3.14

Closes: https://bugs.gentoo.org/796500
Package-Manager: Portage-3.0.28, Repoman-3.0.3
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

2 files changed, 109 insertions, 0 deletions

diff --git a/media-plugins/grilo-plugins/Manifest b/media-plugins/grilo-plugins/Manifest
index 6df21b6d15af..039be2f7599b 100644
--- a/media-plugins/grilo-plugins/Manifest
+++ b/media-plugins/grilo-plugins/Manifest
@@ -1 +1,2 @@
 DIST grilo-plugins-0.3.13.tar.xz 1835320 BLAKE2B 3c39c652700eba0d6c557dbfa700a4f8f1b52ecadb757d7c36b5a3023f096fcb7587f4b054f75eb12ffee61b423abbca73d7847d902450d23b5527024f260058 SHA512 7edccc7366623c3dab56f7c95156327db08efdf038563c9be3e423c517a1117003ef516a069f9a2e877f6a610dad6783d3087d111b039ce7bdc6657124cf8e25
+DIST grilo-plugins-0.3.14.tar.xz 1836512 BLAKE2B 28d633a1565c1bc8329a6a69d4f2d8db5e5887cdce5e56fd4167ab31f293a2c203583b9c2a916977a9642c6acc15933d37e50026e9929587f0f35af688c6a9c4 SHA512 941d9524cfb33e33315ac7575051521d9117ef517b169cca90660dee788252eaf1e6f8171ccc7beede5564d63149e065faf08c3244e17f7c1c193bfb7d2af1f8
diff --git a/media-plugins/grilo-plugins/grilo-plugins-0.3.14.ebuild b/media-plugins/grilo-plugins/grilo-plugins-0.3.14.ebuild
new file mode 100644
index 000000000000..9ad084371036
--- /dev/null
+++ b/media-plugins/grilo-plugins/grilo-plugins-0.3.14.ebuild
@@ -0,0 +1,108 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+LUA_COMPAT=( lua5-3 )
+inherit gnome.org lua-single meson xdg
+
+DESCRIPTION="A collection of plugins for the Grilo framework"
+HOMEPAGE="https://wiki.gnome.org/Projects/Grilo"
+
+LICENSE="LGPL-2.1+"
+SLOT="0.3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="daap chromaprint flickr freebox gnome-online-accounts lua test thetvdb tracker upnp-av +youtube"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="lua? ( ${LUA_REQUIRED_USE} )"
+
+# GOA is only optionally used by flickr and lua-factory plugins (checked at v0.3.13)
+# json-glib used by tmdb and lua; tmdb currently non-optional
+# TODO: validate upnp-av dleyna deps
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=media-libs/grilo-0.3.13:${SLOT}=[playlist]
+	freebox? ( net-dns/avahi[dbus] )
+	>=dev-libs/gom-0.4
+	chromaprint? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		media-plugins/gst-plugins-chromaprint:1.0
+	)
+	dev-libs/json-glib
+	daap? ( >=net-libs/libdmapsharing-2.9.12:3.0 )
+	media-libs/libmediaart:2.0
+	net-libs/libsoup:2.4
+	dev-libs/libxml2:2
+	flickr? (
+		net-libs/liboauth
+		gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.17.91:= )
+	)
+	dev-db/sqlite:3
+	>=dev-libs/totem-pl-parser-3.4.1
+	tracker? ( app-misc/tracker:3= )
+	upnp-av? (
+		net-libs/dleyna-connector-dbus
+		net-misc/dleyna-server
+	)
+	lua? (
+		${LUA_DEPS}
+		app-arch/libarchive
+		dev-libs/libxml2:2
+		gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.17.91:= )
+	)
+	thetvdb? ( app-arch/libarchive )
+	youtube? ( >=dev-libs/libgdata-0.9.1:= )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-text/docbook-xml-dtd:4.5
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	upnp-av? ( >=dev-util/gdbus-codegen-2.44 )
+	virtual/pkgconfig
+	lua? ( dev-util/gperf )
+"
+
+pkg_setup() {
+	use lua && lua-single_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+	sed -i -e "s:'GETTEXT_PACKAGE', meson.project_name():'GETTEXT_PACKAGE', 'grilo-plugins-${SLOT%/*}':" meson.build || die
+	sed -i -e "s:meson.project_name():'grilo-plugins-${SLOT%/*}':" po/meson.build || die
+	sed -i -e "s:meson.project_name():'grilo-plugins-${SLOT%/*}':" help/meson.build || die
+
+	# libdmapsharing-4 is not packaged
+	sed -i -e "s:libdmapsharing4_dep.found():false:" meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable-bookmarks=yes
+		-Denable-chromaprint=$(usex chromaprint yes no)
+		-Denable-dleyna=$(usex upnp-av yes no)
+		-Denable-dmap=$(usex daap yes no)
+		-Denable-filesystem=yes
+		-Denable-flickr=$(usex flickr yes no)
+		-Denable-freebox=$(usex freebox yes no)
+		-Denable-gravatar=yes
+		-Denable-local-metadata=yes
+		-Denable-lua-factory=$(usex lua yes no)
+		-Denable-magnatune=yes
+		-Denable-metadata-store=yes
+		-Denable-opensubtitles=yes
+		-Denable-optical-media=yes
+		-Denable-podcasts=yes
+		-Denable-raitv=yes
+		-Denable-shoutcast=yes
+		-Denable-thetvdb=$(usex thetvdb yes no)
+		-Denable-tmdb=yes
+		-Denable-tracker=no
+		-Denable-tracker3=$(usex tracker yes no)
+		-Denable-youtube=$(usex youtube yes no)
+		$(meson_feature gnome-online-accounts goa)
+		-Dhelp=no
+	)
+	meson_src_configure
+}