kde-apps/kwave: 22.04.1 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index b9c8df9bd670..f8a4419365d4 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-21.12.3.tar.xz 6954384 BLAKE2B abf171bc6585158d5b0984e93a92e599d83b81c855edbfa12f192df208912ae0d5c72c4331528e7d9e88c5486fa5664158136ccf0fe56ab34e4b82051000f43e SHA512 8fd7728af6613f290bd49e41a83822d914e1d0ea3169ca84a3e8b328bbb527a4c6e207a9ec9c47dceb5981a05f1bd30439e305417c0793e81f2731864a1ef21c
 DIST kwave-22.04.0.tar.xz 6925956 BLAKE2B 181cbb713fc4ca9ea597b57530c2f8ed47c1686c0b501c1b3713f120f0df0e8466161f8fde4009009fb34520cc48600724d04304562f0cf40a27fb8a84802873 SHA512 86489d546556d4cc64912baeab8890644be5d21c74e7c7124e826d5e565002b0c2edbb21c7f8a9af7e04edaa9022e97357834a4bf813fe25f7fd7c246de092ad
+DIST kwave-22.04.1.tar.xz 6926340 BLAKE2B 9824a8e857a811a1548b8f0a098c723a3b87fb6f080046e44f229c3e91fad2eb72fa3db3d115f4730a14c97a290ed82e2bce193668f5b72eb38fb63586e1eef4 SHA512 91eae355c5925802e22ac0b952e44c6f2aed041cfe1c86cb2e325cbbf9d63eaee5689f5758db84a01ba03956cae2f77065cdff48832847a62dbe8e9ac8606bf0
diff --git a/kde-apps/kwave/kwave-22.04.1.ebuild b/kde-apps/kwave/kwave-22.04.1.ebuild
new file mode 100644
index 000000000000..15fc461957b8
--- /dev/null
+++ b/kde-apps/kwave/kwave-22.04.1.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.92.0
+QTMIN=5.15.3
+inherit ecm kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}