kde-apps/kwave: 21.12.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 88 insertions, 0 deletions

diff --git a/kde-apps/kwave/Manifest b/kde-apps/kwave/Manifest
index 707e45effb6b..1838afb1bb18 100644
--- a/kde-apps/kwave/Manifest
+++ b/kde-apps/kwave/Manifest
@@ -1,2 +1,3 @@
 DIST kwave-21.08.3.tar.xz 6915844 BLAKE2B 47957ff8f1fcee4ad135c04dcf1bd7610b8c4b25c5a6ec7abf6e44fe6783df56de31bbe6a10a58079bf2a35fa0959a1e1f675546f59473aaf00e3fef06a40fd7 SHA512 111a2159018c93fdd9d2b2627f926c39596dcc40241e15e467bb5909516fe6c6a07cb943a8f8611532c29de9aae28ec7c4eba53f7f38245b25d8b3386c0d69e3
 DIST kwave-21.12.1.tar.xz 6954332 BLAKE2B 436eca6815ce9f83e1bf089c2563178cdb054eb8c02f4302050c99857298323de9e0ea9f06bdc3ba532bf98ed4eb1aced5cf9f2de5f40dc12c3733abdd097467 SHA512 3276c58d82cd04ea56d91af4f16cae0389b970bd97d4d75a54a84c2a0b3d6a6849e02e77891b248942abab9cb4ca3aef21dc5274596a1143573e2b9fcf93980a
+DIST kwave-21.12.2.tar.xz 6954408 BLAKE2B a4d3d41cfcb663a79f0283a986ef0cc3aa0fb5ef870182bc85a80b03486bdb9a1fbbfed55e4afa62993464f3f6c2606669f2d78e4f6d364c07409b13daa2f128 SHA512 df09dcebc70e37dae6e95b334f69d6810fb3a67c698f2c801ee2240dcbeb4e6b80777548903a3ca7738f3439330c06f874c196db910b11300bac67cbce190f4d
diff --git a/kde-apps/kwave/kwave-21.12.2.ebuild b/kde-apps/kwave/kwave-21.12.2.ebuild
new file mode 100644
index 000000000000..051b15651165
--- /dev/null
+++ b/kde-apps/kwave/kwave-21.12.2.ebuild
@@ -0,0 +1,87 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.88.0
+QTMIN=5.15.2
+inherit ecm kde.org
+
+DESCRIPTION="Sound editor built on KDE Frameworks 5 that can edit many types of audio files"
+HOMEPAGE="https://apps.kde.org/kwave/"
+
+LICENSE="CC-BY-SA-3.0 CC0-1.0 GPL-2+ LGPL-2+ handbook? ( FDL-1.2 ) opus? ( BSD-2 )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="alsa flac mp3 opus oss pulseaudio +qtmedia vorbis"
+
+RDEPEND="
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/ktextwidgets-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	media-libs/audiofile:=
+	>=sci-libs/fftw-3
+	media-libs/libsamplerate
+	alsa? ( media-libs/alsa-lib )
+	flac? ( media-libs/flac[cxx] )
+	mp3? (
+		media-libs/id3lib
+		media-libs/libmad
+		|| (
+			media-sound/lame
+			media-sound/toolame
+			media-sound/twolame
+		)
+	)
+	qtmedia? ( >=dev-qt/qtmultimedia-${QTMIN}:5 )
+	opus? (
+		media-libs/libogg
+		media-libs/opus
+	)
+	pulseaudio? ( media-sound/pulseaudio )
+	vorbis? (
+		media-libs/libogg
+		media-libs/libvorbis
+	)
+"
+DEPEND="${RDEPEND}
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+BDEPEND="
+	sys-devel/gettext
+	handbook? ( || (
+		gnome-base/librsvg
+		virtual/imagemagick-tools[png,svg]
+	) )
+"
+
+DOCS=( AUTHORS CHANGES LICENSES README TODO )
+
+src_configure() {
+	local mycmakeargs=(
+		-DDEBUG=$(usex debug)
+		-DWITH_ALSA=$(usex alsa)
+		-DWITH_DOC=$(usex handbook)
+		-DWITH_FLAC=$(usex flac)
+		-DWITH_MP3=$(usex mp3)
+		-DWITH_OGG_VORBIS=$(usex vorbis)
+		-DWITH_OGG_OPUS=$(usex opus)
+		-DWITH_OSS=$(usex oss)
+		-DWITH_PULSEAUDIO=$(usex pulseaudio)
+		-DWITH_QT_AUDIO=$(usex qtmedia)
+	)
+
+	ecm_src_configure
+}