kde-apps/konqueror: 21.11.90 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 91 insertions, 0 deletions

diff --git a/kde-apps/konqueror/Manifest b/kde-apps/konqueror/Manifest
index 383611d35bb7..2f4ceb476408 100644
--- a/kde-apps/konqueror/Manifest
+++ b/kde-apps/konqueror/Manifest
@@ -1 +1,2 @@
 DIST konqueror-21.08.3.tar.xz 7418888 BLAKE2B f9e2902d77871ffc2a093e5b62751bfe5845aa6a86a2b507f01319311d3ea164498c24c5d5637f73c98e146b2453fa8a47606cfcd7e0e6693bf178b52b60f498 SHA512 e9214fcbd4fa2a63660d6d3e5af777cdf3311a059e2ac36cb15373c4944aee310cd3e6eb19d357b13e9154ba6879451e49441c33f88aa57b5c95ab2350f27d21
+DIST konqueror-21.11.90.tar.xz 7427416 BLAKE2B c377d29aeedd76c07ff82b58f1b30007c3b459d494253990baf8afe8cb22ce39adb8b2cf3add19f63d4dd5eef0398842eef7f836030c43fdab48b51624be13b4 SHA512 20cd6c7b9304d47578b6fddd8f7039b46167e2b7875ec576a4a69240311aea8f4947f65c358982ec01d3d36774a00dbbccef257c27e1e18e5852c91f06c743f1
diff --git a/kde-apps/konqueror/konqueror-21.11.90.ebuild b/kde-apps/konqueror/konqueror-21.11.90.ebuild
new file mode 100644
index 000000000000..cec785b5cb95
--- /dev/null
+++ b/kde-apps/konqueror/konqueror-21.11.90.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="true"
+KFMIN=5.88.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit flag-o-matic ecm kde.org optfeature
+
+DESCRIPTION="Web browser and file manager based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/konqueror/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="activities speech X"
+
+# 4 of 4 tests fail. Last checked for 4.0.3
+RESTRICT="test"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtscript-${QTMIN}:5
+	>=dev-qt/qtwebengine-${QTMIN}:5[widgets]
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kbookmarks-${KFMIN}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/kdbusaddons-${KFMIN}:5
+	>=kde-frameworks/kdesu-${KFMIN}:5
+	>=kde-frameworks/kguiaddons-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemviews-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwallet-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kwindowsystem-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	speech? ( >=dev-qt/qtspeech-${QTMIN}:5 )
+	X? ( >=dev-qt/qtx11extras-${QTMIN}:5 )
+"
+DEPEND="${COMMON_DEPEND}
+	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
+"
+RDEPEND="${COMMON_DEPEND}
+	kde-apps/kfind:5
+	kde-plasma/kde-cli-tools:5
+"
+
+src_prepare() {
+	[[ ${CHOST} == *-solaris* ]] && append-ldflags -lmalloc
+
+	ecm_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_DISABLE_FIND_PACKAGE_Hunspell=ON # requires fixing bug 634122
+		$(cmake_use_find_package activities KF5Activities)
+		$(cmake_use_find_package speech Qt5TextToSpeech)
+		$(cmake_use_find_package X X11)
+	)
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "bookmarks support" kde-apps/keditbookmarks:${SLOT}
+		optfeature "filemanager component" kde-apps/dolphin:${SLOT}
+		optfeature "SVG support" kde-apps/svg:${SLOT}
+		optfeature "Java support on webpages" virtual/jre
+	fi
+	ecm_pkg_postinst
+}