dev-python/rpy: Version Bump

Package-Manager: portage-2.2.27
Signed-off-by: Justin Lecher <jlec@gentoo.org>

1 files changed, 53 insertions, 0 deletions

diff --git a/dev-python/rpy/rpy-2.7.8.ebuild b/dev-python/rpy/rpy-2.7.8.ebuild
new file mode 100644
index 000000000000..6c31dd1bfe17
--- /dev/null
+++ b/dev-python/rpy/rpy-2.7.8.ebuild
@@ -0,0 +1,53 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{3,4,5} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 flag-o-matic
+
+MYSLOT=2
+MY_PN=${PN}${MYSLOT}
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python interface to the R Programming Language"
+HOMEPAGE="http://rpy.sourceforge.net/ https://pypi.python.org/pypi/rpy2"
+SRC_URI="mirror://pypi/${MY_PN:0:1}/${MY_PN}/${MY_P}.tar.gz"
+
+LICENSE="AGPL-3 GPL-2 LGPL-2.1 MPL-1.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="test"
+
+RDEPEND="
+	>=dev-lang/R-3.1
+	dev-python/numpy[${PYTHON_USEDEP}]
+	>=dev-python/pandas-0.13.1[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	virtual/python-singledispatch[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]"
+PDEPEND="dev-python/ipython[${PYTHON_USEDEP}]"
+
+# ggplot2 is an optional test dep but not in portage
+S="${WORKDIR}/${MY_P}"
+
+# Tarball absent of doc files in doc folder
+# https://bitbucket.org/rpy2/rpy2/issues/229
+
+python_compile() {
+	if ! python_is_python3; then
+		local CFLAGS=${CFLAGS}
+		append-cflags -fno-strict-aliasing
+	fi
+	distutils-r1_python_compile
+}
+
+python_test() {
+	cd "${BUILD_DIR}"/lib || die
+	${PYTHON} -m 'rpy2.tests' || die
+}