app-emulation/conmon: Bump to version 2.0.22

Package-Manager: Portage-3.0.12, Repoman-3.0.2
Signed-off-by: Zac Medico <zmedico@gentoo.org>

1 files changed, 45 insertions, 0 deletions

diff --git a/app-emulation/conmon/conmon-2.0.22.ebuild b/app-emulation/conmon/conmon-2.0.22.ebuild
new file mode 100644
index 000000000000..967a5d5432eb
--- /dev/null
+++ b/app-emulation/conmon/conmon-2.0.22.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+EGIT_COMMIT="9c34a8663b85e479e0c083801e89a2b2835228ed"
+DESCRIPTION="An OCI container runtime monitor"
+HOMEPAGE="https://github.com/containers/conmon"
+SRC_URI="https://github.com/containers/conmon/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="systemd"
+RESTRICT="test"
+
+RDEPEND="dev-libs/glib:=
+	systemd? ( sys-apps/systemd:= )"
+DEPEND="${RDEPEND}"
+
+S="${WORKDIR}/${PN}-${EGIT_COMMIT}"
+
+src_prepare() {
+	default
+
+	if ! use systemd; then
+		sed -e 's| $(PKG_CONFIG) --exists libsystemd-journal | false |' \
+			-e 's| $(PKG_CONFIG) --exists libsystemd | false |' \
+			-i Makefile || die
+	fi
+}
+
+src_compile() {
+	emake GIT_COMMIT="${EGIT_COMMIT}" \
+		all
+}
+
+src_install() {
+	emake DESTDIR="${D}" \
+		PREFIX="/usr" \
+		install
+	dodir /usr/libexec/podman
+	ln "${ED}/usr/"{bin,libexec/podman}/conmon || die
+	dodoc README.md
+}