app-admin/rsyslog: drop old 8.2304.0

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

2 files changed, 0 insertions, 498 deletions

diff --git a/app-admin/rsyslog/Manifest b/app-admin/rsyslog/Manifest
index dbb3b398703e..6faf0d20eb5e 100644
--- a/app-admin/rsyslog/Manifest
+++ b/app-admin/rsyslog/Manifest
@@ -1,8 +1,6 @@
-DIST rsyslog-8.2304.0.tar.gz 3274047 BLAKE2B 13c0e200acf750e9b40b14153270b0f45358ac8be7a9d0e1fa879e686da9f5a3be3b7915e3c90757a42dbdfbf4c36301cfea213aafe5a0481e1b117f28cf3cf6 SHA512 ca8df2d1d38c78d853b1081c731d9f94cad653a915259b699f3a78a88bcf9c9d1d18b91667ef954fc96a0bd251aa3afd2b6264ce5a6b4ca700687a654507b64f
 DIST rsyslog-8.2306.0.tar.gz 3293380 BLAKE2B cb9ae3fa9f5c8c71491346323b7549d5997b116ec3141296e25871cb8be75f372d1de8b315a6a37e42dd649782790685b30705d1f91151d5561249da508e961d SHA512 4012ea18d49efa75438aa225fec1daafcaadc216cd5c0ecceccdc34688940bbdca9eb19bd9c401e834b023d9b9a5a0870529f7b855bb64c796a55538639dadfc
 DIST rsyslog-8.2308.0.tar.gz 3346424 BLAKE2B fc55323ab9f7e88cc84f32f95531a8cad87aad22bbb7a23303033bb841c8badc4053a8a9fc302611aeb4288efc148708affa7d873e41b07521cbece7e3ccfc45 SHA512 f8bcbbfe2c5c0a7e56203fc4ff285594cfa27fa7c998db2fe065a3f06b9bc30692626787c509b1f5d081a4b176680183b651625c5e3ccb4580ac59f3980ae8a5
 DIST rsyslog-8.2310.0.tar.gz 3349174 BLAKE2B df451f473fdf1714d2ff2bf92afe5e53d00395eb21508fd00c628784fa577aaf6fed597f79c99e64f62bd3a5eadde0748ce08e6c082a24a507fa687055599d70 SHA512 f04e14ede8c35e1799eadc711a6e99dbe56d312c7909c7ebed4d4bd489d310a44a5c2d3ed23968fbf3ccff5b580870d0f3ceeb690deb1d1424420fc9d3220696
-DIST rsyslog-doc-8.2304.0.tar.gz 6586061 BLAKE2B 4680db37eaa8583e21865fafb62ba07ffa235f4184a43bf9a1930166aa26a3bccdc15c43ba26504d157339eb02b05ea95076cf738abc3323eef16e07b42de2af SHA512 1ce8a8cf40cb767e4e62016aa2513f93535a3bd3c47ef34bc1efca007f7afe5c84ca4d30e911903dc8ba529ede0a07feb05ace075b5ef6c1757e5727d11f112e
 DIST rsyslog-doc-8.2306.0.tar.gz 6637017 BLAKE2B 7b4157bbfcdba6c7ac824ef4369bb2141a33989d4e3d1a95ca6b347f3d3eaa98266f7b7a684a8aa0342a8a38f87d7ae144444f888133619e82fb4802ef12d314 SHA512 eb5df4285ed9f5afe884dae497ed77ad96050a9101e94c8d83125c893998094e27d4fad7b7a42391d72cfdc1bf2aeb9fac8f65d61d8aa5c49dda9d0cac81d777
 DIST rsyslog-doc-8.2308.0.tar.gz 6668327 BLAKE2B ca82fa7b69b19ba03fd30adbdf2bdc37eb7f11c714ec7f79d4cfb352fcdf42aae4cf146a6911ec26212de64057ac23416bb2ca27e8001cbe9f9945fd7c7a931e SHA512 f0a581e2a7642d100cdca94125c39cf00acfc3339114ddad067d726f1526941f52ab33c0f5789f9cbd4197b3e1f3c841da86c71886fa97306990193db8d6c935
 DIST rsyslog-doc-8.2310.0.tar.gz 6674428 BLAKE2B e951d564a63c57c1d9d130a315c4bc9f4c25c9cfaf83bece1bbda582eb40260f000c7d9805faca550d8df7b0f6074aff6cc86ff877706cad69909040c3dff5b1 SHA512 cf452f3705680fc81495e940ea7d5ae705a6dbfe0e2ce5a87865c3043f79daaec243df20e8aadd9fac6144a3df8f19d7c56fdf19ec68df78e2fdaffa45096143
diff --git a/app-admin/rsyslog/rsyslog-8.2304.0.ebuild b/app-admin/rsyslog/rsyslog-8.2304.0.ebuild
deleted file mode 100644
index ad15bf7f10b5..000000000000
--- a/app-admin/rsyslog/rsyslog-8.2304.0.ebuild
+++ /dev/null
@@ -1,496 +0,0 @@
-# Copyright 1999-2023 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-PYTHON_COMPAT=( python3_{9..11} )
-
-inherit autotools linux-info python-any-r1 systemd
-
-DESCRIPTION="An enhanced multi-threaded syslogd with database support and more"
-HOMEPAGE="https://www.rsyslog.com/"
-
-if [[ ${PV} == "9999" ]]; then
-	EGIT_REPO_URI="https://github.com/rsyslog/${PN}.git"
-
-	DOC_REPO_URI="https://github.com/rsyslog/${PN}-doc.git"
-
-	inherit git-r3
-else
-	KEYWORDS="amd64 arm arm64 ~hppa ~ia64 ~ppc64 ~riscv ~sparc x86"
-
-	SRC_URI="
-		https://www.rsyslog.com/files/download/${PN}/${P}.tar.gz
-		doc? ( https://www.rsyslog.com/files/download/${PN}/${PN}-doc-${PV}.tar.gz )
-	"
-fi
-
-LICENSE="GPL-3 LGPL-3 Apache-2.0"
-SLOT="0"
-
-IUSE="clickhouse curl dbi debug doc elasticsearch +gcrypt gnutls imhttp"
-IUSE+=" impcap jemalloc kafka kerberos kubernetes mdblookup"
-IUSE+=" mongodb mysql normalize omhttp omhttpfs omudpspoof +openssl"
-IUSE+=" postgres rabbitmq redis relp rfc3195 rfc5424hmac snmp +ssl"
-IUSE+=" systemd test usertools +uuid xxhash zeromq"
-
-RESTRICT="!test? ( test )"
-
-REQUIRED_USE="
-	kubernetes? ( normalize )
-	ssl? ( || ( gnutls openssl ) )
-"
-
-BDEPEND=">=sys-devel/autoconf-archive-2015.02.24
-	sys-apps/lsb-release
-	virtual/pkgconfig
-	test? (
-		jemalloc? ( <sys-libs/libfaketime-0.9.7 )
-		!jemalloc? ( sys-libs/libfaketime )
-		${PYTHON_DEPS}
-	)"
-
-RDEPEND="
-	>=dev-libs/libfastjson-0.99.8:=
-	>=dev-libs/libestr-0.1.9
-	>=sys-libs/zlib-1.2.5
-	curl? ( >=net-misc/curl-7.35.0 )
-	dbi? ( >=dev-db/libdbi-0.8.3 )
-	elasticsearch? ( >=net-misc/curl-7.35.0 )
-	gcrypt? ( >=dev-libs/libgcrypt-1.5.3:= )
-	imhttp? (
-		dev-libs/apr-util
-		www-servers/civetweb
-		virtual/libcrypt:=
-	)
-	impcap? ( net-libs/libpcap )
-	jemalloc? ( >=dev-libs/jemalloc-3.3.1:= )
-	kafka? ( >=dev-libs/librdkafka-0.9.0.99:= )
-	kerberos? ( virtual/krb5 )
-	kubernetes? ( >=net-misc/curl-7.35.0 )
-	mdblookup? ( dev-libs/libmaxminddb:= )
-	mongodb? ( >=dev-libs/mongo-c-driver-1.1.10:= )
-	mysql? ( dev-db/mysql-connector-c:= )
-	normalize? (
-		>=dev-libs/liblognorm-2.0.3:=
-	)
-	clickhouse? ( >=net-misc/curl-7.35.0 )
-	omhttpfs? ( >=net-misc/curl-7.35.0 )
-	omudpspoof? ( >=net-libs/libnet-1.1.6 )
-	postgres? ( >=dev-db/postgresql-8.4.20:= )
-	rabbitmq? ( >=net-libs/rabbitmq-c-0.3.0:= )
-	redis? (
-		>=dev-libs/hiredis-0.11.0:=
-		dev-libs/libevent[threads(+)]
-	)
-	relp? ( >=dev-libs/librelp-1.2.17:= )
-	rfc3195? ( >=dev-libs/liblogging-1.0.1:=[rfc3195] )
-	rfc5424hmac? (
-		>=dev-libs/openssl-0.9.8y:0=
-	)
-	snmp? ( >=net-analyzer/net-snmp-5.7.2 )
-	ssl? (
-		gnutls? ( >=net-libs/gnutls-2.12.23:0= )
-		openssl? (
-			dev-libs/openssl:0=
-		)
-	)
-	systemd? ( >=sys-apps/systemd-234 )
-	uuid? ( sys-apps/util-linux:0= )
-	xxhash? ( dev-libs/xxhash:= )
-	zeromq? (
-		>=net-libs/czmq-4:=[drafts]
-	)"
-
-DEPEND="
-	${RDEPEND}
-	elibc_musl? ( sys-libs/queue-standalone )
-"
-
-if [[ ${PV} == "9999" ]]; then
-	BDEPEND+=" doc? ( >=dev-python/sphinx-1.1.3-r7 )"
-	BDEPEND+=" >=sys-devel/flex-2.5.39-r1"
-	BDEPEND+=" >=sys-devel/bison-2.4.3"
-	BDEPEND+=" >=dev-python/docutils-0.12"
-fi
-
-CONFIG_CHECK="~INOTIFY_USER"
-WARNING_INOTIFY_USER="CONFIG_INOTIFY_USER isn't set. Imfile module on this system will only support polling mode!"
-
-PATCHES=( "${FILESDIR}"/${PN}-8.2112.0-pr5024-configure.patch )
-
-pkg_setup() {
-	use test && python-any-r1_pkg_setup
-}
-
-src_unpack() {
-	if [[ ${PV} == "9999" ]]; then
-		git-r3_fetch
-		git-r3_checkout
-	else
-		unpack ${P}.tar.gz
-	fi
-
-	if use doc; then
-		if [[ ${PV} == "9999" ]]; then
-			local _EGIT_BRANCH=
-			if [[ -n "${EGIT_BRANCH}" ]]; then
-				# Cannot use rsyslog commits/branches for documentation repository
-				_EGIT_BRANCH=${EGIT_BRANCH}
-				unset EGIT_BRANCH
-			fi
-
-			git-r3_fetch "${DOC_REPO_URI}"
-			git-r3_checkout "${DOC_REPO_URI}" "${S}"/docs
-
-			if [[ -n "${_EGIT_BRANCH}" ]]; then
-				# Restore previous EGIT_BRANCH information
-				EGIT_BRANCH=${_EGIT_BRANCH}
-			fi
-		else
-			cd "${S}" || die "Cannot change dir into '${S}'"
-			mkdir docs || die "Failed to create docs directory"
-			cd docs || die "Failed to change dir into '${S}/docs'"
-			unpack ${PN}-doc-${PV}.tar.gz
-		fi
-	fi
-}
-
-src_prepare() {
-	default
-
-	# https://github.com/rsyslog/rsyslog/issues/3626
-	sed -i \
-		-e '\|^#!/bin/bash$|a exit 77' \
-		tests/mmkubernetes-cache-expir*.sh \
-		|| die "Failed to disabled known test failure mmkubernetes-cache-expir*.sh"
-
-	eautoreconf
-}
-
-src_configure() {
-	# Maintainer notes:
-	# * Guardtime support is missing because libgt isn't yet available
-	#   in portage.
-	# * Hadoop's HDFS file system output module is currently not
-	#   supported in Gentoo because nobody is able to test it
-	#   (JAVA dependency).
-	# * dev-libs/hiredis doesn't provide pkg-config (see #504614,
-	#   upstream PR 129 and 136) so we need to export HIREDIS_*
-	#   variables because rsyslog's build system depends on pkg-config.
-
-	if use redis; then
-		export HIREDIS_LIBS="-L${EPREFIX}/usr/$(get_libdir) -lhiredis"
-		export HIREDIS_CFLAGS="-I${EPREFIX}/usr/include"
-	fi
-
-	local myeconfargs=(
-		--disable-debug-symbols
-		--disable-generate-man-pages
-		--without-valgrind-testbench
-		--disable-liblogging-stdlog
-		--disable-imfile-tests  # Some imfile tests fail (noticed in version 8.2208.0)
-		$(use_enable test testbench)
-		$(use_enable test libfaketime)
-		$(use_enable test extended-tests)
-		# Input Plugins without dependencies
-		--enable-imbatchreport
-		--enable-imdiag
-		--enable-imdocker
-		--enable-imfile
-		--enable-improg
-		--enable-impstats
-		--enable-imptcp
-		# Message Modificiation Plugins without dependencies
-		--enable-mmanon
-		--enable-mmaudit
-		--enable-mmcount
-		--enable-mmfields
-		--enable-mmjsonparse
-		--enable-mmpstrucdata
-		--enable-mmrm1stspace
-		--enable-mmsequence
-		--enable-mmtaghostname
-		--enable-mmutf8fix
-		# Output Modification Plugins without dependencies
-		--enable-mail
-		--enable-omprog
-		--enable-omruleset
-		--enable-omstdout
-		--enable-omuxsock
-		# Misc
-		--enable-fmhash
-		--enable-fmunflatten
-		$(use_enable xxhash fmhash-xxhash)
-		--enable-pmaixforwardedfrom
-		--enable-pmciscoios
-		--enable-pmcisconames
-		--enable-pmdb2diag
-		--enable-pmlastmsg
-		$(use_enable normalize pmnormalize)
-		--enable-pmnull
-		--enable-pmpanngfw
-		--enable-pmsnare
-		# DB
-		$(use_enable dbi libdbi)
-		$(use_enable mongodb ommongodb)
-		$(use_enable mysql)
-		$(use_enable postgres pgsql)
-		$(use_enable redis imhiredis)
-		$(use_enable redis omhiredis)
-		# Debug
-		$(use_enable debug)
-		$(use_enable debug diagtools)
-		$(use_enable debug valgrind)
-		# Misc
-		$(use_enable clickhouse)
-		$(use_enable curl fmhttp)
-		$(use_enable elasticsearch)
-		$(use_enable gcrypt libgcrypt)
-		$(use_enable imhttp)
-		$(use_enable impcap)
-		$(use_enable jemalloc)
-		$(use_enable kafka imkafka)
-		$(use_enable kafka omkafka)
-		$(use_enable kerberos gssapi-krb5)
-		$(use_enable kubernetes mmkubernetes)
-		$(use_enable normalize mmnormalize)
-		$(use_enable mdblookup mmdblookup)
-		$(use_enable omhttp)
-		$(use_enable omhttpfs)
-		$(use_enable omudpspoof)
-		$(use_enable rabbitmq omrabbitmq)
-		$(use_enable relp)
-		$(use_enable rfc3195)
-		$(use_enable rfc5424hmac mmrfc5424addhmac)
-		$(use_enable snmp)
-		$(use_enable snmp mmsnmptrapd)
-		$(use_enable gnutls)
-		$(use_enable openssl)
-		$(use_enable systemd imjournal)
-		$(use_enable systemd omjournal)
-		$(use_enable usertools)
-		$(use_enable uuid)
-		$(use_enable zeromq imczmq)
-		$(use_enable zeromq omczmq)
-		--with-systemdsystemunitdir="$(systemd_get_systemunitdir)"
-	)
-
-	econf "${myeconfargs[@]}"
-}
-
-src_compile() {
-	default
-
-	if use doc && [[ "${PV}" == "9999" ]]; then
-		einfo "Building documentation ..."
-		local doc_dir="${S}/docs"
-		cd "${doc_dir}" || die "Cannot chdir into \"${doc_dir}\"!"
-		sphinx-build -b html source build || die "Building documentation failed!"
-	fi
-}
-
-src_test() {
-	local _has_increased_ulimit=
-
-	# Sometimes tests aren't executable (i.e. when added via patch)
-	einfo "Adjusting permissions of test scripts ..."
-	find "${S}"/tests -type f -name '*.sh' \! -perm -111 -exec chmod a+x '{}' \; || \
-		die "Failed to adjust test scripts permission"
-
-	if ulimit -n 3072; then
-		_has_increased_ulimit="true"
-	fi
-
-	if ! emake --jobs 1 check; then
-		eerror "Test suite failed! :("
-
-		if [[ -z "${_has_increased_ulimit}" ]]; then
-			eerror "Probably because open file limit couldn't be set to 3072."
-		fi
-
-		if has userpriv ${FEATURES}; then
-			eerror "Please try to reproduce the test suite failure with FEATURES=-userpriv " \
-				"before you submit a bug report."
-		fi
-
-	fi
-}
-
-src_install() {
-	local DOCS=(
-		AUTHORS
-		ChangeLog
-		"${FILESDIR}"/README.gentoo
-	)
-
-	use doc && local HTML_DOCS=( "${S}/docs/build/." )
-
-	default
-
-	newconfd "${FILESDIR}/${PN}.confd-r1" ${PN}
-	newinitd "${FILESDIR}/${PN}.initd-r1" ${PN}
-
-	systemd_newunit "${FILESDIR}/${PN}.service" ${PN}.service
-
-	keepdir /var/empty/dev
-	keepdir /var/spool/${PN}
-	keepdir /etc/ssl/${PN}
-	keepdir /etc/${PN}.d
-
-	insinto /etc
-	newins "${FILESDIR}/${PN}.conf" ${PN}.conf
-
-	insinto /etc/rsyslog.d/
-	newins "${FILESDIR}/50-default-r1.conf" 50-default.conf
-
-	insinto /etc/logrotate.d/
-	newins "${FILESDIR}/${PN}-r1.logrotate" ${PN}
-
-	if use mysql; then
-		insinto /usr/share/${PN}/scripts/mysql
-		doins plugins/ommysql/createDB.sql
-	fi
-
-	if use postgres; then
-		insinto /usr/share/${PN}/scripts/pgsql
-		doins plugins/ompgsql/createDB.sql
-	fi
-
-	find "${ED}" -name '*.la' -delete || die
-}
-
-pkg_postinst() {
-	local advertise_readme=0
-
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		# This is a new installation
-
-		advertise_readme=1
-
-		if use mysql || use postgres; then
-			echo
-			elog "Sample SQL scripts for MySQL & PostgreSQL have been installed to:"
-			elog "  /usr/share/doc/${PF}/scripts"
-		fi
-
-		if use ssl; then
-			echo
-			elog "To create a default CA and certificates for your server and clients, run:"
-			elog "  emerge --config =${PF}"
-			elog "on your logging server. You can run it several times,"
-			elog "once for each logging client. The client certificates will be signed"
-			elog "using the CA certificate generated during the first run."
-		fi
-	fi
-
-	if [[ ${advertise_readme} -gt 0 ]]; then
-		# We need to show the README file location
-
-		echo ""
-		elog "Please read"
-		elog ""
-		elog "  ${EPREFIX}/usr/share/doc/${PF}/README.gentoo*"
-		elog ""
-		elog "for more details."
-	fi
-}
-
-pkg_config() {
-	if ! use ssl; then
-		einfo "There is nothing to configure for rsyslog unless you"
-		einfo "used USE=ssl to build it."
-		return 0
-	fi
-
-	if ! hash certtool &>/dev/null; then
-		die "certtool not found! Is net-libs/gnutls[tools] is installed?"
-	fi
-
-	# Make sure the certificates directory exists
-	local CERTDIR="${EROOT}/etc/ssl/${PN}"
-	if [[ ! -d "${CERTDIR}" ]]; then
-		mkdir "${CERTDIR}" || die
-	fi
-	einfo "Your certificates will be stored in ${CERTDIR}"
-
-	# Create a default CA if needed
-	if [[ ! -f "${CERTDIR}/${PN}_ca.cert.pem" ]]; then
-		einfo "No CA key and certificate found in ${CERTDIR}, creating them for you..."
-		certtool --generate-privkey \
-			--outfile "${CERTDIR}/${PN}_ca.privkey.pem" || die
-		chmod 400 "${CERTDIR}/${PN}_ca.privkey.pem"
-
-		cat > "${T}/${PF}.$$" <<- _EOF
-		cn = Portage automated CA
-		ca
-		cert_signing_key
-		expiration_days = 3650
-		_EOF
-
-		certtool --generate-self-signed \
-			--load-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
-			--outfile "${CERTDIR}/${PN}_ca.cert.pem" \
-			--template "${T}/${PF}.$$" || die
-		chmod 400 "${CERTDIR}/${PN}_ca.privkey.pem"
-
-		# Create the server certificate
-		echo
-		einfon "Please type the Common Name of the SERVER you wish to create a certificate for: "
-		read -r CN
-
-		einfo "Creating private key and certificate for server ${CN}..."
-		certtool --generate-privkey \
-			--outfile "${CERTDIR}/${PN}_${CN}.key.pem" || die
-		chmod 400 "${CERTDIR}/${PN}_${CN}.key.pem"
-
-		cat > "${T}/${PF}.$$" <<- _EOF
-		cn = ${CN}
-		tls_www_server
-		dns_name = ${CN}
-		expiration_days = 3650
-		_EOF
-
-		certtool --generate-certificate \
-			--outfile "${CERTDIR}/${PN}_${CN}.cert.pem" \
-			--load-privkey "${CERTDIR}/${PN}_${CN}.key.pem" \
-			--load-ca-certificate "${CERTDIR}/${PN}_ca.cert.pem" \
-			--load-ca-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
-			--template "${T}/${PF}.$$" &>/dev/null
-		chmod 400 "${CERTDIR}/${PN}_${CN}.cert.pem"
-
-	else
-		einfo "Found existing ${CERTDIR}/${PN}_ca.cert.pem, skipping CA and SERVER creation."
-	fi
-
-	# Create a client certificate
-	echo
-	einfon "Please type the Common Name of the CLIENT you wish to create a certificate for: "
-	read -r CN
-
-	einfo "Creating private key and certificate for client ${CN}..."
-	certtool --generate-privkey \
-		--outfile "${CERTDIR}/${PN}_${CN}.key.pem" || die
-	chmod 400 "${CERTDIR}/${PN}_${CN}.key.pem"
-
-	cat > "${T}/${PF}.$$" <<- _EOF
-	cn = ${CN}
-	tls_www_client
-	dns_name = ${CN}
-	expiration_days = 3650
-	_EOF
-
-	certtool --generate-certificate \
-		--outfile "${CERTDIR}/${PN}_${CN}.cert.pem" \
-		--load-privkey "${CERTDIR}/${PN}_${CN}.key.pem" \
-		--load-ca-certificate "${CERTDIR}/${PN}_ca.cert.pem" \
-		--load-ca-privkey "${CERTDIR}/${PN}_ca.privkey.pem" \
-		--template "${T}/${PF}.$$" || die
-	chmod 400 "${CERTDIR}/${PN}_${CN}.cert.pem"
-
-	rm -f "${T}/${PF}.$$"
-
-	echo
-	einfo "Here is the documentation on how to encrypt your log traffic:"
-	einfo " https://www.rsyslog.com/doc/rsyslog_tls.html"
-}