# Copyright 1999-2015 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/dev-python/pypy/pypy-2.6.0.ebuild,v 1.1 2015/06/04 18:46:39 mgorny Exp $

EAPI=5

PYTHON_COMPAT=( python2_7 pypy )
inherit check-reqs eutils multilib multiprocessing pax-utils python-any-r1 toolchain-funcs versionator

CPY_PATCHSET_VERSION="2.7.10-0"

DESCRIPTION="A fast, compliant alternative implementation of the Python language"
HOMEPAGE="http://pypy.org/"
SRC_URI="https://bitbucket.org/pypy/pypy/downloads/${P}-src.tar.bz2"

LICENSE="MIT"
SLOT="0/$(get_version_component_range 1-2 ${PV})"
KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
IUSE="bzip2 +jit low-memory ncurses sandbox shadowstack sqlite cpu_flags_x86_sse2"

DEPEND=">=sys-libs/zlib-1.1.3:0=
	virtual/libffi:0=
	virtual/libintl:0=
	dev-libs/expat:0=
	dev-libs/openssl:0=[-bindist]
	bzip2? ( app-arch/bzip2:0= )
	ncurses? ( sys-libs/ncurses:0= )
	app-arch/xz-utils
	${PYTHON_DEPS}"

S="${WORKDIR}/${P}-src"

pkg_pretend() {
	if use low-memory; then
		if ! python_is_installed pypy; then
			eerror "USE=low-memory requires a (possibly old) version of dev-python/pypy"
			eerror "or dev-python/pypy-bin being installed. Please install it using e.g.:"
			eerror
			eerror "  $ emerge -1v dev-python/pypy-bin"
			eerror
			eerror "before attempting to build dev-python/pypy[low-memory]."
			die "dev-python/pypy-bin (or dev-python/pypy) needs to be installed for USE=low-memory"
		fi

		CHECKREQS_MEMORY="1750M"
		use amd64 && CHECKREQS_MEMORY="3500M"
	else
		CHECKREQS_MEMORY="3G"
		use amd64 && CHECKREQS_MEMORY="6G"
	fi

	check-reqs_pkg_pretend

	[[ ${PYPY_BINPKG_STORE} ]] || die 'PYPY_BINPKG_STORE unset, wtf?!'
}

pkg_setup() {
	pkg_pretend

	if python_is_installed pypy; then
		if [[ ! ${EPYTHON} || ${EPYTHON} == pypy ]] || use low-memory; then
			einfo "Using already-installed PyPy to perform the translation."
			local EPYTHON=pypy
		else
			einfo "Using ${EPYTHON} to perform the translation. Please note that upstream"
			einfo "recommends using PyPy for that. If you wish to do so, please unset"
			einfo "the EPYTHON variable."
		fi
	fi

	python-any-r1_pkg_setup

	local cpu
	if use amd64; then
		# common denominator between Intel & AMD
		cpu='x86-64'
	elif use x86; then
		if use cpu_flags_x86_sse2; then
			# lowest with SSE2
			cpu='pentium-m'
		else
			# lowest with SSE, compat. with athlon-xp
			# TODO: do we want to support something older?
			cpu='pentium3'
		fi
	else
		die "Unsupported arch ${ARCH}"
	fi

	export CFLAGS="-march=${cpu} -mtune=generic -O2 -pipe"
	export CXXFLAGS=${CFLAGS}

	elog "CFLAGS: ${CFLAGS}"
}

src_prepare() {
	epatch "${FILESDIR}"/2.5.0-shared-lib.patch	# 517002

	epatch_user
}

src_compile() {
	tc-export CC

	local jit_backend
	if use jit; then
		jit_backend='--jit-backend='

		# We only need the explicit sse2 switch for x86.
		# On other arches we can rely on autodetection which uses
		# compiler macros. Plus, --jit-backend= doesn't accept all
		# the modern values...

		if use x86; then
			if use cpu_flags_x86_sse2; then
				jit_backend+=x86
			else
				jit_backend+=x86-without-sse2
			fi
		else
			jit_backend+=auto
		fi
	fi

	local args=(
		--shared
		$(usex jit -Ojit -O2)
		$(usex shadowstack --gcrootfinder=shadowstack '')
		$(usex sandbox --sandbox '')

		${jit_backend}
		--make-jobs=$(makeopts_jobs)

		pypy/goal/targetpypystandalone
	)

	# Avoid linking against libraries disabled by use flags
	local opts=(
		bzip2:bz2
		ncurses:_minimal_curses
	)

	local opt
	for opt in "${opts[@]}"; do
		local flag=${opt%:*}
		local mod=${opt#*:}

		args+=(
			$(usex ${flag} --withmod --withoutmod)-${mod}
		)
	done

	local interp=( "${PYTHON}" )
	if use low-memory; then
		interp=( env PYPY_GC_MAX_DELTA=200MB
			"${PYTHON}" --jit loop_longevity=300 )
	fi

	set -- "${interp[@]}" rpython/bin/rpython --batch "${args[@]}"
	echo -e "\033[1m${@}\033[0m"
	"${@}" || die "compile error"

	pax-mark m "${ED%/}${INSDESTTREE}/pypy-c"
}

src_install() {
	local flags=( bzip2 jit ncurses sandbox shadowstack )
	use x86 && flags+=( cpu_flags_x86_sse2 )
	local f suffix="-${ARCH}"

	for f in ${flags[@]}; do
		use ${f} && suffix+="+${f#cpu_flags_x86_}"
	done

	local BIN_P=pypy-bin-${PV}

	einfo "Zipping PyPy ..."
	mkdir "${BIN_P}${suffix}"{,/include} || die
	mv pypy-c libpypy-c.so "${BIN_P}${suffix}"/ || die
	mv include/pypy_* "${BIN_P}${suffix}"/include/ || die
	chmod +x "${BIN_P}${suffix}"/pypy-c || die

	tar -cf "${BIN_P}${suffix}.tar" "${BIN_P}${suffix}" || die
	xz -vz9e "${BIN_P}${suffix}.tar" || die
}

# Yup, very hacky.
pkg_preinst() {
	# integrity check.
	[[ ${PYPY_BINPKG_STORE} ]] || die 'PYPY_BINPKG_STORE unset, wtf?!'
	mkdir -p "${ROOT%/}${PYPY_BINPKG_STORE}" || die
	mv "${S}"/*.tar.xz "${ROOT%/}${PYPY_BINPKG_STORE}" || die
}