kde-apps/kaddressbook: 22.04.2 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 75 insertions, 0 deletions

diff --git a/kde-apps/kaddressbook/Manifest b/kde-apps/kaddressbook/Manifest
new file mode 100644
index 0000000000..6d0ccd9b90
--- /dev/null
+++ b/kde-apps/kaddressbook/Manifest
@@ -0,0 +1 @@
+DIST kaddressbook-22.04.2.tar.xz 3350128 BLAKE2B 26dfd1de1716c25d9ef3350650a20041d859e942e40e4b2b78466efe6a55ba40af393baecceb59ea31210db7882104a7211fa054c3aaa15cdf928cfcf18e8783 SHA512 65085b413f6dbe037a5aba5a3f349882879197da85459c90dbf6777360a8405dbf2d79dac2994b28f682f81b4994550c21940e180f244dcdbaacdbd50bf8d140
diff --git a/kde-apps/kaddressbook/kaddressbook-22.04.2.ebuild b/kde-apps/kaddressbook/kaddressbook-22.04.2.ebuild
new file mode 100644
index 0000000000..19c5d8d092
--- /dev/null
+++ b/kde-apps/kaddressbook/kaddressbook-22.04.2.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="optional"
+ECM_TEST="forceoptional"
+PVCUT=$(ver_cut 1-3)
+KFMIN=5.92.0
+QTMIN=5.15.2
+VIRTUALX_REQUIRED="test"
+inherit ecm kde.org optfeature
+
+DESCRIPTION="Address book application based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/kaddressbook/"
+
+LICENSE="GPL-2+ handbook? ( FDL-1.2+ )"
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
+IUSE="telemetry"
+
+DEPEND="
+	dev-libs/grantlee:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-apps/akonadi-${PVCUT}:5
+	>=kde-apps/akonadi-contacts-${PVCUT}:5
+	>=kde-apps/akonadi-search-${PVCUT}:5
+	>=kde-apps/grantleetheme-${PVCUT}:5
+	>=kde-apps/kontactinterface-${PVCUT}:5
+	>=kde-apps/libgravatar-${PVCUT}:5
+	>=kde-apps/libkdepim-${PVCUT}:5
+	>=kde-apps/pimcommon-${PVCUT}:5
+	>=kde-frameworks/kcmutils-${KFMIN}:5
+	>=kde-frameworks/kcodecs-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcontacts-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/kitemmodels-${KFMIN}:5
+	>=kde-frameworks/kjobwidgets-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	>=kde-frameworks/prison-${KFMIN}:5
+	telemetry? ( >=dev-libs/kuserfeedback-1.2.0:5 )
+"
+RDEPEND="${DEPEND}
+	>=kde-apps/kdepim-runtime-${PVCUT}:5
+"
+
+PATCHES=( "${FILESDIR}/${PN}-22.03.80-unused-dep.patch" )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package telemetry KUserFeedback)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	if [[ -z "${REPLACING_VERSIONS}" ]]; then
+		optfeature "Postal addresses" kde-apps/kdepim-addons:${SLOT}
+	fi
+	ecm_pkg_postinst
+}