blob: f5b9d33d1189878533a8e4677b8d8ca87ea95f2c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
|
# Copyright 1999-2007 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/app-laptop/hdapsd/hdapsd-20060409-r1.ebuild,v 1.3 2007/08/29 18:55:52 genstef Exp $
inherit eutils linux-info toolchain-funcs
PROTECT_VER="2"
DESCRIPTION="IBM ThinkPad Harddrive Active Protection disk head parking daemon"
HOMEPAGE="http://hdaps.sourceforge.net/"
SRC_URI="http://www.dresco.co.uk/hdaps/${P}.c
mirror://gentoo/hdaps_protect-patches-${PROTECT_VER}.tar.bz2"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~x86"
IUSE=""
RDEPEND=""
S=${WORKDIR}
CONFIG_CHECK="SENSORS_HDAPS"
ERROR_SENSORS_HDAPS="${P} requires support for HDAPS (CONFIG_SENSORS_HDAPS)"
src_unpack() {
cp "${DISTDIR}"/${P}.c .
unpack hdaps_protect-patches-${PROTECT_VER}.tar.bz2
}
src_compile() {
$(tc-getCC) ${CFLAGS} "${P}".c -o hdapsd || die "failed to compile"
}
src_install() {
dosbin hdapsd
newconfd "${FILESDIR}"/hdapsd.conf hdapsd
newinitd "${FILESDIR}"/hdapsd.init hdapsd
# Install our kernel patches
dodoc *.patch "${FILESDIR}"/hdaps-Z60m.patch
}
# Yes, this sucks as the source location may change, kernel sources may not be
# installed, but we try our best anyway
kernel_patched() {
get_version
if grep -qs "blk_protect_register" "${KERNEL_DIR}"/block/ll_rw_blk.c ; then
einfo "Your kernel has already been patched for blk_freeze"
return 0
fi
return 1
}
pkg_config() {
kernel_patched && return 0
local docdir="${ROOT}/usr/share/doc/${PF}/"
local p="hdaps_protect-${KV_MAJOR}.${KV_MINOR}.${KV_PATCH}.patch.gz"
# We need to find our FILESDIR as it's now lost
if [[ ! -e ${docdir}/${p} ]] ; then
eerror "We don't have a patch for kernel ${KV_MAJOR}.${KV_MINOR}.${KV_PATCH} yet"
return 1
fi
if [[ ! -d ${KERNEL_DIR} ]] ; then
eerror "Kernel sources not found!"
return 1
fi
cd "${KERNEL_DIR}"
epatch "${docdir}/${p}"
# This is just a nice to have for me as I use a Z60m myself
if ! grep -q "Z60m" "${KERNEL_DIR}"/drivers/hwmon/hdaps.c ; then
epatch "${docdir}"/hdaps-Z60m.patch.gz
fi
echo
einfo "Now you should rebuild your kernel, its modules"
einfo "and then install them."
}
pkg_postinst(){
[[ -n $(ls "${ROOT}"/sys/block/*/queue/protect 2>/dev/null) ]] && return 0
if ! kernel_patched ; then
ewarn "Your kernel has NOT been patched for blk_freeze"
elog "The ebuild can attempt to patch your kernel like so"
elog " emerge --config =${PF}"
fi
}
|
GitWeb