blob: bc892a8077967f5a67c06fda0aa449e9248f46f0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
|
# Copyright 1999-2009 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/gnome-extra/evolution-data-server/evolution-data-server-2.24.5-r3.ebuild,v 1.7 2009/08/02 10:48:57 armin76 Exp $
EAPI="2"
inherit db-use eutils flag-o-matic gnome2 autotools versionator
DESCRIPTION="Evolution groupware backend"
HOMEPAGE="http://www.gnome.org/projects/evolution/"
LICENSE="LGPL-2 Sleepycat"
SLOT="0"
KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 sparc x86 ~x86-fbsd"
IUSE="doc ipv6 kerberos gnome-keyring krb4 ldap ssl"
RDEPEND=">=dev-libs/glib-2.16.1
>=x11-libs/gtk+-2.10
>=gnome-base/orbit-2.9.8
>=gnome-base/libbonobo-2.20.3
>=gnome-base/gconf-2
>=gnome-base/libglade-2
>=gnome-base/libgnome-2
>=dev-libs/libxml2-2
>=net-libs/libsoup-2.4
gnome-keyring? ( >=gnome-base/gnome-keyring-2.20.1 )
>=dev-db/sqlite-3.5
ssl? (
>=dev-libs/nspr-4.4
>=dev-libs/nss-3.9 )
>=gnome-base/libgnomeui-2
sys-libs/zlib
=sys-libs/db-4*
ldap? ( >=net-nds/openldap-2.0 )
kerberos? ( virtual/krb5 )
krb4? ( app-crypt/mit-krb5[krb4] )"
DEPEND="${RDEPEND}
>=dev-util/pkgconfig-0.9
>=dev-util/intltool-0.35.5
>=gnome-base/gnome-common-2
>=dev-util/gtk-doc-am-1.9
doc? ( >=dev-util/gtk-doc-1.9 )"
DOCS="ChangeLog MAINTAINERS NEWS TODO"
pkg_setup() {
G2CONF="${G2CONF}
$(use_with ldap openldap)
$(use_with krb4 krb4 /usr)
$(use_with kerberos krb5 /usr)
$(use_enable ssl nss)
$(use_enable ssl smime)
$(use_enable ipv6)
$(use_enable gnome-keyring)
--with-libdb=/usr/$(get_libdir)"
}
src_prepare() {
gnome2_src_prepare
# Adjust to gentoo's /etc/service
epatch "${FILESDIR}"/${PN}-1.2.0-gentoo_etc_services.patch
# Fix broken libdb build
epatch "${FILESDIR}"/${PN}-1.11.3-no-libdb.patch
# Rewind in camel-disco-diary to fix a crash
epatch "${FILESDIR}"/${PN}-1.8.0-camel-rewind.patch
# Fix building evo-exchange with --as-needed, upstream bug #342830
epatch "${FILESDIR}"/${PN}-2.23.6-as-needed.patch
# Fix S/MIME verification. Bug #258867
epatch "${FILESDIR}"/${P}-CVE-2009-0547.patch
# Fix S/MIME message display, bug #258867
epatch "${FILESDIR}"/${P}-fix-body.patch
# Fix NTLM SASL authentication. Bug #261203
epatch "${FILESDIR}"/${PN}-CVE-2009-0582.patch
if use doc; then
sed "/^TARGET_DIR/i \GTKDOC_REBASE=/usr/bin/gtkdoc-rebase" \
-i gtk-doc.make || die "sed 1 failed"
else
sed "/^TARGET_DIR/i \GTKDOC_REBASE=$(type -P true)" \
-i gtk-doc.make || die "sed 2 failed"
fi
# gtk-doc-am and gnome-common needed for this
intltoolize --force --copy --automake || die "intltoolize failed"
eautoreconf
# Use NSS/NSPR only if 'ssl' is enabled.
if use ssl ; then
sed -i -e "s|mozilla-nss|nss|
s|mozilla-nspr|nspr|" "${S}"/configure || die "sed failed"
G2CONF="${G2CONF} --enable-nss=yes"
else
G2CONF="${G2CONF} --without-nspr-libs --without-nspr-includes \
--without-nss-libs --without-nss-includes"
fi
# /usr/include/db.h is always db-1 on FreeBSD
# so include the right dir in CPPFLAGS
append-cppflags "-I$(db_includedir)"
}
src_install() {
gnome2_src_install
if use ldap; then
MY_MAJORV=$(get_version_component_range 1-2)
insinto /etc/openldap/schema
doins "${FILESDIR}"/calentry.schema || die "doins failed"
dosym "${D}"/usr/share/${PN}-${MY_MAJORV}/evolutionperson.schema /etc/openldap/schema/evolutionperson.schema
fi
}
pkg_postinst() {
gnome2_pkg_postinst
if use ldap; then
elog ""
elog "LDAP schemas needed by evolution are installed in /etc/openldap/schema"
fi
}
|
GitWeb