From dfcae544882b15dabcf45564fbf0ee18b6346089 Mon Sep 17 00:00:00 2001
From: Jan Matejka <yac@gentoo.org>
Date: Sat, 8 Mar 2014 01:34:43 +0000
Subject: fixes bgo#486746

(Portage version: 2.2.7/cvs/Linux x86_64, signed Manifest commit with key F97A36A1)
---
 www-servers/tornado/tornado-3.1.1-r1.ebuild | 52 +++++++++++++++++++++++++++++
 1 file changed, 52 insertions(+)
 create mode 100644 www-servers/tornado/tornado-3.1.1-r1.ebuild

(limited to 'www-servers/tornado/tornado-3.1.1-r1.ebuild')

diff --git a/www-servers/tornado/tornado-3.1.1-r1.ebuild b/www-servers/tornado/tornado-3.1.1-r1.ebuild
new file mode 100644
index 000000000000..4f06656c5ffe
--- /dev/null
+++ b/www-servers/tornado/tornado-3.1.1-r1.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/www-servers/tornado/tornado-3.1.1-r1.ebuild,v 1.1 2014/03/08 01:34:43 yac Exp $
+
+EAPI=5
+
+PYTHON_COMPAT=( python{2_6,2_7,3_2,3_3} pypy2_0 )
+
+inherit distutils-r1
+
+DESCRIPTION="Scalable, non-blocking web server and tools"
+HOMEPAGE="http://www.tornadoweb.org/ http://pypi.python.org/pypi/tornado"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
+IUSE="curl test"
+
+RDEPEND="curl? ( dev-python/pycurl[$(python_gen_usedep 'python2*')] )"
+DEPEND="${RDEPEND}
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		python_targets_python2_6? (
+			dev-python/twisted-names[python_targets_python2_6]
+			virtual/python-unittest2[python_targets_python2_6]
+		)
+		python_targets_python2_7? ( dev-python/twisted-names[python_targets_python2_7] )
+	)
+"
+
+REQUIRED_USE="curl? ( || ( $(python_gen_useflags python2*) ) )"
+
+PATCHES=(
+	"${FILESDIR}/unittest2-import-issue-1005.patch"
+	"${FILESDIR}/${P}-py2_6-tests-fix.patch"
+)
+
+src_test() {
+	# The test server tries to bind at an unused port but suffers
+	# a race condition in it. Seems to be fixed already.
+	# https://github.com/facebook/tornado/blob/master/tornado/test/process_test.py#L64
+	local DISTUTILS_NO_PARALLEL_BUILD=1
+
+	distutils-r1_src_test
+}
+
+python_test() {
+	cd "${TMPDIR}" || die
+	"${PYTHON}" -m tornado.test.runtests || die "Tests fail with ${EPYTHON}"
+}
-- 
cgit v1.2.3-65-gdbad