From da5991772a9eb00674630f5754562a99a93fa861 Mon Sep 17 00:00:00 2001
From: Alexandre Rostovtsev <tetromino@gentoo.org>
Date: Fri, 28 Oct 2011 20:55:54 +0000
Subject: New ebuild, moved from gnome overlay. Needed for
 gnome-color-manager-3.2.

(Portage version: 2.2.0_alpha71/cvs/Linux x86_64)
---
 media-libs/mash/mash-0.2.0-r1.ebuild | 48 ++++++++++++++++++++++++++++++++++++
 1 file changed, 48 insertions(+)
 create mode 100644 media-libs/mash/mash-0.2.0-r1.ebuild

(limited to 'media-libs/mash/mash-0.2.0-r1.ebuild')

diff --git a/media-libs/mash/mash-0.2.0-r1.ebuild b/media-libs/mash/mash-0.2.0-r1.ebuild
new file mode 100644
index 000000000000..eab46fb58194
--- /dev/null
+++ b/media-libs/mash/mash-0.2.0-r1.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2011 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-libs/mash/mash-0.2.0-r1.ebuild,v 1.1 2011/10/28 20:55:54 tetromino Exp $
+
+EAPI="4"
+GCONF_DEBUG="no"
+GNOME2_LA_PUNT="yes"
+
+# clutter.eclass does not support .xz tarballs
+inherit gnome2 versionator
+RV=($(get_version_components))
+SRC_URI="http://source.clutter-project.org/sources/${PN}/${RV[0]}.${RV[1]}/${P}.tar.xz"
+
+DESCRIPTION="A library for rendering 3D models with Clutter"
+HOMEPAGE="http://wiki.clutter-project.org/wiki/Mash"
+
+LICENSE="LGPL-2.1"
+SLOT="0.2"
+IUSE="doc examples +introspection"
+KEYWORDS="~amd64 ~x86"
+
+# Automagically detects x11-libs/mx, but only uses it for building examples.
+# Note: mash is using a bundled copy of rply because mash developers have
+# modified its API by adding extra arguments to various functions.
+RDEPEND=">=dev-libs/glib-2.16:2
+	>=media-libs/clutter-1.5.10:1.0[introspection?]
+	virtual/opengl
+
+	introspection? ( >=dev-libs/gobject-introspection-0.6.1 )"
+DEPEND="${RDEPEND}
+	dev-util/pkgconfig
+	doc? ( >=dev-util/gtk-doc-1.14 )"
+
+pkg_setup() {
+	DOCS="AUTHORS NEWS README"
+	G2CONF="${G2CONF}
+		--disable-static
+		$(use_enable introspection)"
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use examples; then
+		insinto /usr/share/doc/${PF}/examples
+		doins example/{*.c,*.ply}
+	fi
+}
-- 
cgit v1.2.3-65-gdbad