1 files changed, 69 insertions, 0 deletions
diff --git a/dev-tcltk/tclreadline/tclreadline-2.1.0-r4.ebuild b/dev-tcltk/tclreadline/tclreadline-2.1.0-r4.ebuild
new file mode 100644
index 000000000000..d2fc83fbe418
--- /dev/null
+++ b/dev-tcltk/tclreadline/tclreadline-2.1.0-r4.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-tcltk/tclreadline/tclreadline-2.1.0-r4.ebuild,v 1.1 2013/11/23 08:38:24 jlec Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=true
+
+inherit autotools-utils multilib toolchain-funcs
+
+DEBIAN_PATCH=12
+
+DESCRIPTION="Readline extension to TCL"
+HOMEPAGE="http://tclreadline.sf.net/"
+SRC_URI="
+	mirror://sourceforge/${PN}/${P}.tar.gz
+	mirror://debian/pool/main/t/${PN}/${PN}_${PV}-${DEBIAN_PATCH}.debian.tar.gz"
+
+SLOT="0"
+LICENSE="BSD"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs"
+
+DEPEND="
+	dev-lang/tcl
+	sys-libs/readline"
+RDEPEND="${DEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${P}-gold.patch
+	"${FILESDIR}"/${P}-alloc-free.patch
+	"${FILESDIR}"/${P}-rl-executing-macro.patch
+	"${FILESDIR}"/${P}-rl-history-expand.patch
+	"${FILESDIR}"/${P}-rl-prompt.patch
+	"${WORKDIR}"/debian/patches/complete_nontcl.patch
+	"${WORKDIR}"/debian/patches/completion_matches.patch
+	"${WORKDIR}"/debian/patches/completion_pbug.patch
+	"${WORKDIR}"/debian/patches/kfreebsd.patch
+	"${WORKDIR}"/debian/patches/link.patch
+	"${WORKDIR}"/debian/patches/manpage.patch
+	"${WORKDIR}"/debian/patches/memuse.patch
+#	"${WORKDIR}"/debian/patches/tclrldir.patch
+	"${WORKDIR}"/debian/patches/tclshpath.patch
+	"${WORKDIR}"/debian/patches/tinfo.patch
+	"${WORKDIR}"/debian/patches/varnames.patch
+
+	)
+
+src_prepare() {
+	sed \
+		-e "s/AM_CONFIG_HEADER/AC_CONFIG_HEADERS/" \
+		-e "/^TCLRL_LIBDIR/s:lib:$(get_libdir):g" \
+		-i configure.in || die
+	mv configure.{in,ac} || die
+	sed \
+		-e 's:configure.in:configure.ac:g' \
+		-i "${WORKDIR}"/debian/patches/* || die
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-tcl="${EPREFIX}/usr/$(get_libdir)"
+		--with-tcl-includes="${EPREFIX}/usr/include"
+		--with-readline-includes="${EPREFIX}/usr/include"
+		--with-readline-library="-lreadline"
+		)
+	autotools-utils_src_configure
+}