new upstream release

(Portage version: 2.2.14/cvs/Linux x86_64, signed Manifest commit with key EC917A6D)

2 files changed, 107 insertions, 1 deletions

diff --git a/x11-terms/mlterm/ChangeLog b/x11-terms/mlterm/ChangeLog
index 831255d828fb..2686206dc547 100644
--- a/x11-terms/mlterm/ChangeLog
+++ b/x11-terms/mlterm/ChangeLog
@@ -1,6 +1,11 @@
 # ChangeLog for x11-terms/mlterm
 # Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/ChangeLog,v 1.102 2014/10/31 11:48:26 hattya Exp $
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/ChangeLog,v 1.103 2014/12/29 12:43:09 hattya Exp $
+
+*mlterm-3.4.1 (29 Dec 2014)
+
+  29 Dec 2014; Akinori Hattori <hattya@gentoo.org> +mlterm-3.4.1.ebuild:
+  new upstream release
 
 *mlterm-3.4.0 (31 Oct 2014)
 
diff --git a/x11-terms/mlterm/mlterm-3.4.1.ebuild b/x11-terms/mlterm/mlterm-3.4.1.ebuild
new file mode 100644
index 000000000000..3e656ad95d08
--- /dev/null
+++ b/x11-terms/mlterm/mlterm-3.4.1.ebuild
@@ -0,0 +1,101 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/x11-terms/mlterm/mlterm-3.4.1.ebuild,v 1.1 2014/12/29 12:43:09 hattya Exp $
+
+EAPI="5"
+
+inherit autotools-utils eutils
+
+DESCRIPTION="A multi-lingual terminal emulator"
+HOMEPAGE="http://mlterm.sourceforge.net/"
+SRC_URI="mirror://sourceforge/mlterm/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~hppa ~ppc ~ppc64 ~x86"
+IUSE="bidi cairo debug fcitx gtk ibus libssh2 m17n-lib nls regis scim static-libs uim utempter xft"
+
+RDEPEND="x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	bidi? ( dev-libs/fribidi )
+	cairo? ( x11-libs/cairo )
+	fcitx? ( app-i18n/fcitx )
+	gtk? ( x11-libs/gtk+ )
+	ibus? ( app-i18n/ibus )
+	libssh2? ( net-libs/libssh2 )
+	m17n-lib? ( dev-libs/m17n-lib )
+	nls? ( virtual/libintl )
+	regis? (
+		|| (
+			media-libs/sdl-ttf
+			media-libs/sdl2-ttf
+		)
+	)
+	scim? ( app-i18n/scim )
+	uim? ( app-i18n/uim )
+	utempter? ( sys-libs/libutempter )
+	xft? ( x11-libs/libXft )"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )"
+
+DOCS=( ChangeLog README doc/{en,ja} )
+
+AUTOTOOLS_PRUNE_LIBTOOL_FILES="all"
+
+src_prepare() {
+	# default config
+	sed -i \
+		-e "/ icon_path =/aicon_path = ${EPREFIX}/usr/share/pixmaps/mlterm-icon.svg" \
+		-e "/ scrollbar_view_name =/ascrollbar_view_name = sample" \
+		etc/main
+
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local myeconfargs=(
+		--with-type-engines=xcore$(usex xft ",xft" "")$(usex cairo ",cairo" "")
+		--enable-optimize-redrawing
+		--enable-vt52
+		$(use_enable bidi fribidi)
+		$(use_enable debug)
+		$(use_enable fcitx)
+		$(use_enable ibus)
+		$(use_enable libssh2 ssh2)
+		$(use_enable m17n-lib m17nlib)
+		$(use_enable nls)
+		$(use_enable scim)
+		$(use_enable uim)
+		$(use_enable utempter utmp)
+	)
+
+	local scrollbars="sample,extra"
+	local tools="mlclient,mlcc,mlmenu,mlterm-zoom"
+	if use gtk; then
+		myeconfargs+=(--with-imagelib=gdk-pixbuf)
+		if has_version x11-libs/gtk+:3; then
+			myeconfargs+=(--with-gtk=3.0)
+		fi
+		scrollbars+=",pixmap_engine"
+		tools+=",mlconfig,mlimgloader"
+	fi
+	if use regis; then
+		tools+=",registobmp"
+	fi
+	myeconfargs+=(--with-scrollbars="${scrollbars}")
+	myeconfargs+=(--with-tools="${tools}")
+
+	addpredict /dev/ptmx
+	autotools-utils_src_configure
+}
+
+src_install () {
+	autotools-utils_src_install
+	docinto contrib/icon
+	dodoc contrib/icon/README
+
+	doicon contrib/icon/mlterm*
+	make_desktop_entry mlterm mlterm mlterm-icon "System;TerminalEmulator"
+}