Bump, unstable release, used by gnome-shell-3.4

(Portage version: 2.2.0_alpha95/cvs/Linux x86_64)

2 files changed, 71 insertions, 1 deletions

diff --git a/net-libs/telepathy-glib/ChangeLog b/net-libs/telepathy-glib/ChangeLog
index 7917cba217c6..72794929ec4d 100644
--- a/net-libs/telepathy-glib/ChangeLog
+++ b/net-libs/telepathy-glib/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for net-libs/telepathy-glib
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/ChangeLog,v 1.103 2012/03/25 17:03:06 armin76 Exp $
+# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/ChangeLog,v 1.104 2012/03/26 16:50:27 nirbheek Exp $
+
+*telepathy-glib-0.17.7 (26 Mar 2012)
+
+  26 Mar 2012; Nirbheek Chauhan <nirbheek@gentoo.org>
+  +telepathy-glib-0.17.7.ebuild:
+  Bump, unstable release, used by gnome-shell-3.4
 
   25 Mar 2012; Raúl Porcel <armin76@gentoo.org> telepathy-glib-0.16.3.ebuild:
   alpha/ia64/sparc stable wrt #393007
diff --git a/net-libs/telepathy-glib/telepathy-glib-0.17.7.ebuild b/net-libs/telepathy-glib/telepathy-glib-0.17.7.ebuild
new file mode 100644
index 000000000000..90bed2da92ea
--- /dev/null
+++ b/net-libs/telepathy-glib/telepathy-glib-0.17.7.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/net-libs/telepathy-glib/telepathy-glib-0.17.7.ebuild,v 1.1 2012/03/26 16:50:27 nirbheek Exp $
+
+EAPI="4"
+PYTHON_DEPEND="2:2.5"
+
+inherit python virtualx
+
+DESCRIPTION="GLib bindings for the Telepathy D-Bus protocol."
+HOMEPAGE="http://telepathy.freedesktop.org"
+SRC_URI="http://telepathy.freedesktop.org/releases/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~x86-linux"
+IUSE="debug +introspection +vala"
+
+RDEPEND=">=dev-libs/glib-2.30.0:2
+	>=dev-libs/dbus-glib-0.90
+	introspection? ( >=dev-libs/gobject-introspection-1.30 )
+	vala? (
+		>=dev-lang/vala-0.14.0:0.14[vapigen]
+		>=dev-libs/gobject-introspection-1.30 )"
+DEPEND="${RDEPEND}
+	dev-libs/libxslt
+	>=dev-util/pkgconfig-0.21"
+
+src_prepare() {
+	python_convert_shebangs -r 2 examples tests tools
+	default_src_prepare
+}
+
+src_configure() {
+	local myconf
+
+	if use vala; then
+		myconf="--enable-introspection
+			VALAC=$(type -p valac-0.14)
+			VAPIGEN=$(type -p vapigen-0.14)"
+	fi
+
+	econf --disable-static \
+		--disable-installed-tests \
+		PYTHON=$(PYTHON -2 -a) \
+		$(use_enable debug backtrace) \
+		$(use_enable debug debug-cache) \
+		$(use_enable introspection) \
+		$(use_enable vala vala-bindings) \
+		${myconf}
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	# Needs dbus for tests (auto-launched)
+	Xemake -j1 check
+}
+
+src_install() {
+	emake install DESTDIR="${D}"
+	dodoc AUTHORS ChangeLog NEWS README
+
+	find "${D}" -name '*.la' -exec rm -f '{}' +
+}