Version bump, drop support for gtkhtml slot that is unmaintained for ages and will be removed soon, drop old.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key A188FBD4)

3 files changed, 111 insertions, 108 deletions

diff --git a/mail-client/balsa/ChangeLog b/mail-client/balsa/ChangeLog
index d64ba671363c..f82c871d05da 100644
--- a/mail-client/balsa/ChangeLog
+++ b/mail-client/balsa/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for mail-client/balsa
-# Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/ChangeLog,v 1.126 2013/04/01 18:24:59 ago Exp $
+# Copyright 1999-2014 Gentoo Foundation; Distributed under the GPL v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/ChangeLog,v 1.127 2014/06/22 15:42:14 pacho Exp $
+
+*balsa-2.4.14 (22 Jun 2014)
+
+  22 Jun 2014; Pacho Ramos <pacho@gentoo.org> +balsa-2.4.14.ebuild,
+  -balsa-2.4.12.ebuild:
+  Version bump, drop support for gtkhtml slot that is unmaintained for ages and
+  will be removed soon, drop old.
 
   01 Apr 2013; Agostino Sarubbo <ago@gentoo.org> balsa-2.4.13.ebuild:
   Stable for sparc, wrt bug #458984
diff --git a/mail-client/balsa/balsa-2.4.12.ebuild b/mail-client/balsa/balsa-2.4.12.ebuild
deleted file mode 100644
index 6fa9accee3cd..000000000000
--- a/mail-client/balsa/balsa-2.4.12.ebuild
+++ /dev/null
@@ -1,106 +0,0 @@
-# Copyright 1999-2012 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/balsa-2.4.12.ebuild,v 1.5 2012/10/28 15:56:20 armin76 Exp $
-
-EAPI="4"
-GCONF_DEBUG="no"
-
-inherit eutils gnome2
-
-DESCRIPTION="Email client for GNOME"
-HOMEPAGE="http://pawsa.fedorapeople.org/balsa/"
-SRC_URI="http://pawsa.fedorapeople.org/${PN}/${P}.tar.bz2"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="alpha amd64 ppc sparc x86"
-# Doesn't currently build with -gnome
-IUSE="crypt gnome gtkhtml +gtkspell kerberos ldap libnotify networkmanager rubrica sqlite ssl webkit xface"
-
-# TODO: esmtp can be optional
-RDEPEND=">=dev-libs/glib-2.16:2
-	>=x11-libs/gtk+-2.18:2
-	dev-libs/gmime:2.6
-	dev-libs/libunique:1
-	>=net-libs/libesmtp-1.0.3
-	net-mail/mailbase
-	media-libs/libcanberra[gtk]
-	x11-themes/hicolor-icon-theme
-	x11-themes/gnome-icon-theme
-	crypt? ( >=app-crypt/gpgme-1.0 )
-	gnome? (
-		>=gnome-base/orbit-2
-		>=gnome-base/libbonobo-2.0
-		>=gnome-base/libgnome-2.0
-		>=gnome-base/libgnomeui-2.0
-		>=gnome-base/gconf-2.0:2
-		>=gnome-base/gnome-keyring-2.20
-		>=x11-libs/gtksourceview-2.10:2.0 )
-	gtkhtml? ( >=gnome-extra/gtkhtml-3.14:3.14 )
-	sqlite? ( >=dev-db/sqlite-2.8 )
-	libnotify? ( >=x11-libs/libnotify-0.7 )
-	gtkspell? (
-		app-text/gtkspell:2
-		app-text/enchant )
-	!gtkspell? ( app-text/aspell )
-	kerberos? ( app-crypt/mit-krb5 )
-	ldap? ( net-nds/openldap )
-	networkmanager? ( >=net-misc/networkmanager-0.7 )
-	rubrica? ( dev-libs/libxml2:2 )
-	ssl? ( dev-libs/openssl )
-	webkit? ( >=net-libs/webkit-gtk-1.5.1:2 )
-	xface? ( >=media-libs/compface-1.5.1 )"
-DEPEND="${RDEPEND}
-	dev-util/intltool
-	virtual/pkgconfig
-	sys-devel/gettext
-	>=app-text/scrollkeeper-0.1.4
-	app-text/gnome-doc-utils"
-
-REQUIRED_USE="gtkhtml? ( !webkit )"
-
-DOCS="AUTHORS ChangeLog HACKING NEWS README TODO docs/*"
-
-pkg_setup() {
-	if use crypt ; then
-		G2CONF="${G2CONF} --with-gpgme=gpgme-config"
-	else
-		G2CONF="${G2CONF} --without-gpgme"
-	fi
-
-	if use webkit || use gtkhtml; then
-		if use gtkhtml ; then
-			G2CONF="${G2CONF} --with-html-widget=gtkhtml3"
-		else
-			G2CONF="${G2CONF} --with-html-widget=webkit"
-		fi
-	else
-		G2CONF="${G2CONF} --with-html-widget=no"
-	fi
-
-	G2CONF="${G2CONF}
-		--disable-pcre
-		--enable-gregex
-		--enable-threads
-		--with-gmime=2.6
-		--with-unique
-		--with-canberra
-		$(use_with gnome)
-		$(use_with gnome gtksourceview)
-		$(use_with gtkspell)
-		$(use_with kerberos gss)
-		$(use_with ldap)
-		$(use_with libnotify)
-		$(use_with networkmanager nm)
-		$(use_with rubrica)
-		$(use_with sqlite)
-		$(use_with ssl)
-		$(use_with xface compface)"
-}
-
-src_prepare() {
-	# Fix documentation
-	epatch "${FILESDIR}/${PN}-2.4.11-doc-fixes.patch"
-
-	gnome2_src_prepare
-}
diff --git a/mail-client/balsa/balsa-2.4.14.ebuild b/mail-client/balsa/balsa-2.4.14.ebuild
new file mode 100644
index 000000000000..46ca2552045f
--- /dev/null
+++ b/mail-client/balsa/balsa-2.4.14.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/mail-client/balsa/balsa-2.4.14.ebuild,v 1.1 2014/06/22 15:42:14 pacho Exp $
+
+EAPI="5"
+GCONF_DEBUG="no"
+
+inherit eutils gnome2
+
+DESCRIPTION="Email client for GNOME"
+HOMEPAGE="http://pawsa.fedorapeople.org/balsa/"
+SRC_URI="http://pawsa.fedorapeople.org/${PN}/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
+# Doesn't currently build with -gnome
+IUSE="crypt gnome +gtkspell kerberos ldap libnotify networkmanager rubrica sqlite ssl webkit xface"
+
+# TODO: esmtp can be optional
+RDEPEND="
+	>=dev-libs/glib-2.16:2
+	>=x11-libs/gtk+-2.18:2
+	dev-libs/gmime:2.6
+	dev-libs/libunique:1
+	>=net-libs/libesmtp-1.0.3:=
+	net-mail/mailbase
+	media-libs/libcanberra:=[gtk]
+	x11-themes/hicolor-icon-theme
+	crypt? ( >=app-crypt/gpgme-1.0:= )
+	gnome? (
+		>=gnome-base/orbit-2
+		>=gnome-base/libbonobo-2.0
+		>=gnome-base/libgnome-2.0
+		>=gnome-base/libgnomeui-2.0
+		>=gnome-base/gconf-2.0:2
+		>=gnome-base/gnome-keyring-2.20
+		>=x11-libs/gtksourceview-2.10:2.0 )
+	sqlite? ( >=dev-db/sqlite-2.8:= )
+	libnotify? ( >=x11-libs/libnotify-0.7:= )
+	gtkspell? (
+		app-text/gtkspell:2
+		app-text/enchant )
+	!gtkspell? ( app-text/aspell )
+	kerberos? ( app-crypt/mit-krb5 )
+	ldap? ( net-nds/openldap )
+	networkmanager? ( >=net-misc/networkmanager-0.7 )
+	rubrica? ( dev-libs/libxml2:2 )
+	ssl? ( dev-libs/openssl:= )
+	webkit? ( >=net-libs/webkit-gtk-1.5.1:2 )
+	xface? ( >=media-libs/compface-1.5.1:= )
+"
+DEPEND="${RDEPEND}
+	dev-util/intltool
+	virtual/pkgconfig
+	sys-devel/gettext
+	>=app-text/scrollkeeper-0.1.4
+	app-text/gnome-doc-utils
+"
+
+src_prepare() {
+	# Fix documentation
+	epatch "${FILESDIR}/${PN}-2.4.11-doc-fixes.patch"
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf
+	DOCS="AUTHORS ChangeLog HACKING NEWS README TODO docs/*"
+
+	if use crypt ; then
+		myconf+=" --with-gpgme=gpgme-config"
+	else
+		myconf+=" --without-gpgme"
+	fi
+
+	if use webkit; then
+		myconf+=" --with-html-widget=webkit"
+	else
+		myconf+=" --with-html-widget=no"
+	fi
+
+	gnome2_src_configure \
+		--disable-pcre \
+		--enable-gregex \
+		--enable-threads \
+		--with-gmime=2.6 \
+		--with-unique \
+		--with-canberra \
+		$(use_with gnome) \
+		$(use_with gnome gtksourceview) \
+		$(use_with gtkspell) \
+		$(use_with kerberos gss) \
+		$(use_with ldap) \
+		$(use_with libnotify) \
+		$(use_with networkmanager nm) \
+		$(use_with rubrica) \
+		$(use_with sqlite) \
+		$(use_with ssl) \
+		$(use_with xface compface) \
+		${myconf}
+}