gnome-extra/zeitgeist-datasources: vala_depend is a function not a variable; Version Bump

(Portage version: 2.2.0_alpha173/cvs/Linux x86_64, signed Manifest commit with key 8009D6F070EB7916)

4 files changed, 118 insertions, 3 deletions

diff --git a/gnome-extra/zeitgeist-datasources/ChangeLog b/gnome-extra/zeitgeist-datasources/ChangeLog
index e226d6203347..24927ab114a6 100644
--- a/gnome-extra/zeitgeist-datasources/ChangeLog
+++ b/gnome-extra/zeitgeist-datasources/ChangeLog
@@ -1,6 +1,13 @@
 # ChangeLog for gnome-extra/zeitgeist-datasources
 # Copyright 1999-2013 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/zeitgeist-datasources/ChangeLog,v 1.14 2013/04/18 07:53:39 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/zeitgeist-datasources/ChangeLog,v 1.15 2013/04/30 16:41:26 jlec Exp $
+
+*zeitgeist-datasources-0.8.1 (30 Apr 2013)
+
+  30 Apr 2013; Justin Lecher <jlec@gentoo.org>
+  zeitgeist-datasources-0.8.0.1.ebuild, +zeitgeist-datasources-0.8.1.ebuild,
+  metadata.xml:
+  vala_depend is a function not a variable; Version Bump
 
   18 Apr 2013; Justin Lecher <jlec@gentoo.org>
   zeitgeist-datasources-0.8.0.1.ebuild:
diff --git a/gnome-extra/zeitgeist-datasources/metadata.xml b/gnome-extra/zeitgeist-datasources/metadata.xml
index 6f216feae380..2b8e13c104c0 100644
--- a/gnome-extra/zeitgeist-datasources/metadata.xml
+++ b/gnome-extra/zeitgeist-datasources/metadata.xml
@@ -24,6 +24,7 @@ datahub does not track events like opening websites etc.
     <flag name="xchat">Zeitgeist plugin for <pkg>net-irc/xchat-gnome</pkg> as data source</flag>
     <flag name="rhythmbox">Zeitgeist plugin for <pkg>media-sound/rhythmbox</pkg> as data source</flag>
     <flag name="firefox">Zeitgeist plugin for <pkg>www-client/firefox</pkg> as data source</flag>
+    <flag name="thunderbird">Zeitgeist plugin for <pkg>mail-client/thunderbird</pkg> as data source</flag>
     <flag name="totem">Zeitgeist plugin for <pkg>media-video/totem</pkg> as data source</flag>
   </use>
 </pkgmetadata>
diff --git a/gnome-extra/zeitgeist-datasources/zeitgeist-datasources-0.8.0.1.ebuild b/gnome-extra/zeitgeist-datasources/zeitgeist-datasources-0.8.0.1.ebuild
index 0e12831b0448..75da55f6b94b 100644
--- a/gnome-extra/zeitgeist-datasources/zeitgeist-datasources-0.8.0.1.ebuild
+++ b/gnome-extra/zeitgeist-datasources/zeitgeist-datasources-0.8.0.1.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2013 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/gnome-extra/zeitgeist-datasources/zeitgeist-datasources-0.8.0.1.ebuild,v 1.13 2013/04/18 07:53:39 jlec Exp $
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/zeitgeist-datasources/zeitgeist-datasources-0.8.0.1.ebuild,v 1.14 2013/04/30 16:41:26 jlec Exp $
 
 EAPI=4
 
@@ -49,7 +49,7 @@ RDEPEND="
 #		|| ( >=www-client/firefox-4.0 >=www-client/firefox-bin-4.0 )
 #		net-libs/xulrunner )
 DEPEND="${RDEPEND}
-	${vala_depend}"
+	$(vala_depend)"
 PDEPEND="gnome-extra/zeitgeist"
 
 PLUGINS="bzr chrome eog geany vim emacs tomboy telepathy xchat firefox-40-libzg"
diff --git a/gnome-extra/zeitgeist-datasources/zeitgeist-datasources-0.8.1.ebuild b/gnome-extra/zeitgeist-datasources/zeitgeist-datasources-0.8.1.ebuild
new file mode 100644
index 000000000000..fa63ec5d9a30
--- /dev/null
+++ b/gnome-extra/zeitgeist-datasources/zeitgeist-datasources-0.8.1.ebuild
@@ -0,0 +1,107 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/gnome-extra/zeitgeist-datasources/zeitgeist-datasources-0.8.1.ebuild,v 1.1 2013/04/30 16:41:26 jlec Exp $
+
+EAPI=5
+
+AUTOTOOLS_AUTORECONF=true
+VALA_MIN_API_VERSION=0.14
+PYTHON_COMPAT=( python{2_6,2_7}  )
+
+inherit autotools-utils eutils mono multilib python-single-r1 versionator vala
+
+DIR_PV=$(get_version_component_range 1-2)
+DIR_PV2=$(get_version_component_range 1-3)
+
+DESCRIPTION="Plugins whose work is to push activities as events into Zeitgeist daemon"
+HOMEPAGE="https://launchpad.net/zeitgeist-datasources/ http://zeitgeist-project.com/"
+SRC_URI="http://launchpad.net/zeitgeist-datasources/${DIR_PV}/${DIR_PV2}/+download/${P}.tar.gz"
+
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+LICENSE="GPL-3"
+PLUGINS_IUSE="bzr emacs firefox geany mono telepathy thunderbird tomboy vim xchat"
+PLUGINS="bzr emacs firefox geany monodevelop telepathy thunderbird tomboy vim xchat"
+IUSE="${PLUGINS_IUSE} static-libs"
+
+RDEPEND="
+	dev-libs/libzeitgeist
+	x11-libs/gtk+:2
+	emacs? ( virtual/emacs )
+	firefox? ( || ( >=www-client/firefox-4.0 >=www-client/firefox-bin-4.0 ) )
+	geany? ( dev-util/geany )
+	mono? ( dev-util/monodevelop )
+	telepathy? (
+		dev-python/telepathy-python[${PYTHON_USEDEP}]
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		dev-python/pygobject[${PYTHON_USEDEP}]
+		)
+	tomboy? (
+		app-misc/tomboy
+		dev-dotnet/gtk-sharp
+		dev-dotnet/mono-addins
+		dev-dotnet/zeitgeist-sharp
+		dev-python/dbus-python[${PYTHON_USEDEP}]
+		)
+	vim? ( app-editors/vim[python] )
+	xchat? ( net-irc/xchat-gnome )
+"
+DEPEND="${RDEPEND}
+	$(vala_depend)"
+PDEPEND="gnome-extra/zeitgeist"
+
+src_prepare() {
+	rm bzr/bzr-icon-64.png || die
+	sed \
+		-e '/bzr-icon-64.png/d' \
+		-i bzr/Makefile.am || die
+	sed \
+		-e '/^allowed_plugin/s:^:#:g' \
+		-i configure.ac || die
+
+	SEARCH='$(datadir)/opt/google/chrome/resources'
+	REPLACE="/usr/$(get_libdir)/chromium-browser/resources"
+	sed \
+		-e "s:${SEARCH}:${REPLACE}:" \
+		-i chrome/Makefile.* || die
+
+	sed \
+		-e "/^extensiondir/s:= .*:= \$(libdir)/firefox/extensions:g" \
+		-e "/^xul_extdir/s:xul-ext-zeitgeist:xpcom-firefox@zeitgeist-project.com:g" \
+		-i firefox/extension/Makefile.am || die
+
+	sed \
+		-e "/^extensiondir/s:= .*:= \$(libdir)/thunderbird/extensions:g" \
+		-e "/^xul_extdir/s:xul-ext-zeitgeist:thunderbird@zeitgeist-project.com:g" \
+		-i thunderbird/extension/Makefile.am || die
+
+	sed \
+		-e 's:vim72:vimfiles:' \
+		-i vim/Makefile.* || die
+	sed \
+		-e "s:/xchat/:/xchat-gnome/:g" \
+		-i xchat/Makefile.* || die
+
+	vala_src_prepare
+	autotools-utils_src_prepare
+}
+
+src_configure() {
+	local i myplugins
+
+	for i in ${PLUGINS}; do
+		case ${i} in
+			monodevelop )
+				use mono && myplugins+=( ${i} )
+				;;
+			* )
+				use ${i} && myplugins+=( ${i} )
+				;;
+		esac
+	done
+
+	local myeconfargs=(
+		allowed_plugins="${myplugins[@]}"
+		)
+	autotools-utils_src_configure
+}