Version bump. Convert to python-r1, bug 508860 by Martin von Gagern. Use mirror://imagemagick in SRC_URI.

(Portage version: 2.2.10/cvs/Linux x86_64, signed Manifest commit with key 0BBEEA1FEA4843A4)

1 files changed, 57 insertions, 0 deletions

diff --git a/dev-python/pythonmagick/pythonmagick-0.9.10.ebuild b/dev-python/pythonmagick/pythonmagick-0.9.10.ebuild
new file mode 100644
index 000000000000..fde992a77941
--- /dev/null
+++ b/dev-python/pythonmagick/pythonmagick-0.9.10.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2014 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-python/pythonmagick/pythonmagick-0.9.10.ebuild,v 1.1 2014/04/27 15:51:02 floppym Exp $
+
+EAPI="5"
+AUTOTOOLS_AUTORECONF=1
+AUTOTOOLS_PRUNE_LIBTOOL_FILES="modules"
+PYTHON_COMPAT=( python{2_7,3_2,3_3} )
+WANT_AUTOMAKE="1.12"
+
+inherit autotools-utils eutils python-r1
+
+MY_PN="PythonMagick"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Python bindings for ImageMagick"
+HOMEPAGE="http://www.imagemagick.org/script/api.php"
+SRC_URI="mirror://imagemagick/python/${MY_P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE=""
+
+RDEPEND=">=dev-libs/boost-1.48[python,${PYTHON_USEDEP}]
+	>=media-gfx/imagemagick-6.4"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.9.10-Makefile.am.patch"
+	"${FILESDIR}/${PN}-0.9.10-ax_boost_python.patch"
+)
+
+src_configure() {
+	local myeconfargs=( --disable-static )
+
+	python_configure() {
+		if ! python_is_python3; then
+			local -x CXXFLAGS="${CXXFLAGS} -fno-strict-aliasing"
+		fi
+		autotools-utils_src_configure --with-boost-python=boost_python-${EPYTHON#python}
+	}
+
+	python_parallel_foreach_impl python_configure
+}
+
+src_compile() {
+	python_foreach_impl autotools-utils_src_compile
+}
+
+src_install() {
+	python_foreach_impl autotools-utils_src_install
+}