Fix bug 261792.

(Portage version: 2.1.6.7/cvs/Linux x86_64)

2 files changed, 87 insertions, 1 deletions

diff --git a/dev-libs/soprano/ChangeLog b/dev-libs/soprano/ChangeLog
index 4cf52e397963..7be7a921df4f 100644
--- a/dev-libs/soprano/ChangeLog
+++ b/dev-libs/soprano/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-libs/soprano
 # Copyright 1999-2009 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-libs/soprano/ChangeLog,v 1.17 2009/02/15 22:05:45 scarabeus Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/soprano/ChangeLog,v 1.18 2009/03/09 02:34:34 ali_bush Exp $
+
+*soprano-2.2.1-r1 (09 Mar 2009)
+
+  09 Mar 2009; Alistair Bush <ali_bush@gentoo.org> +soprano-2.2.1-r1.ebuild:
+  Fix bug 261792. Java class function were overridden resulting in invalid
+  java environment.
 
   15 Feb 2009; Tomas Chvatal <scarabeus@gentoo.org> soprano-2.2.1.ebuild:
   Update deps. Per bug #259069.
diff --git a/dev-libs/soprano/soprano-2.2.1-r1.ebuild b/dev-libs/soprano/soprano-2.2.1-r1.ebuild
new file mode 100644
index 000000000000..1faf49e88755
--- /dev/null
+++ b/dev-libs/soprano/soprano-2.2.1-r1.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2009 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-libs/soprano/soprano-2.2.1-r1.ebuild,v 1.1 2009/03/09 02:34:34 ali_bush Exp $
+
+EAPI="2"
+
+JAVA_PKG_OPT_USE="sesame2"
+
+inherit base cmake-utils flag-o-matic java-pkg-opt-2
+
+DESCRIPTION="Soprano is a library which provides a nice QT interface to RDF storage solutions."
+HOMEPAGE="http://sourceforge.net/projects/soprano"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.bz2"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
+IUSE="+clucene debug doc elibc_FreeBSD redland +sesame2"
+
+COMMON_DEPEND="
+	x11-libs/qt-core:4
+	x11-libs/qt-dbus:4
+	clucene? ( dev-cpp/clucene )
+	redland? (
+		>=dev-libs/rasqal-0.9.15
+		>=dev-libs/redland-1.0.6
+		media-libs/raptor
+	)
+	sesame2? ( >=virtual/jdk-1.6.0 )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-util/cmake-2.6.2
+	doc? ( app-doc/doxygen )
+"
+RDEPEND="${COMMON_DEPEND}"
+
+PATCHES=( "${FILESDIR}/${PN}-make-optional-targets.patch" )
+
+CMAKE_IN_SOURCE_BUILD="1"
+
+pkg_setup() {
+	java-pkg-opt-2_pkg_setup
+	if ! use redland && ! use sesame2; then
+		ewarn "You explicitly disabled default soprano backend and haven't chosen other one."
+		ewarn "Applications using soprano may need at least one backend functional."
+		ewarn "If you experience any problems, enable any of those USE flags:"
+		ewarn "redland, sesame2"
+	fi
+}
+
+src_prepare() {
+	base_src_prepare
+}
+
+src_configure() {
+	# Fix for missing pthread.h linking
+	# NOTE: temporarely fix until a better cmake files patch will be provided.
+	use elibc_FreeBSD && append-ldflags "-lpthread"
+
+	mycmakeargs="${mycmakeargs}
+		-DENABLE_tests=OFF
+		$(cmake-utils_use_enable clucene CLucene)
+		$(cmake-utils_use_enable redland Redland)
+		$(cmake-utils_use_enable sesame2 Sesame2)
+		$(cmake-utils_use_enable doc docs)"
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+}
+
+src_test() {
+	mycmakeargs="${mycmakeargs}
+		-DENABLE_tests=ON"
+	cmake-utils_src_configure
+	cmake-utils_src_compile
+	ctest --extra-verbose || die "Tests failed."
+}