New snapshot.

(Portage version: 2.2.0_alpha86/cvs/Linux x86_64)

2 files changed, 105 insertions, 1 deletions

diff --git a/sys-kernel/linux-firmware/ChangeLog b/sys-kernel/linux-firmware/ChangeLog
index 3772187cbabd..89db7759ad99 100644
--- a/sys-kernel/linux-firmware/ChangeLog
+++ b/sys-kernel/linux-firmware/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for sys-kernel/linux-firmware
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/sys-kernel/linux-firmware/ChangeLog,v 1.32 2012/02/03 22:56:13 chithanh Exp $
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/linux-firmware/ChangeLog,v 1.33 2012/02/21 21:41:45 chithanh Exp $
+
+*linux-firmware-20120219 (21 Feb 2012)
+
+  21 Feb 2012; Chí-Thanh Christopher Nguyễn <chithanh@gentoo.org>
+  +linux-firmware-20120219.ebuild:
+  New snapshot.
 
 *linux-firmware-20120125 (03 Feb 2012)
 
diff --git a/sys-kernel/linux-firmware/linux-firmware-20120219.ebuild b/sys-kernel/linux-firmware/linux-firmware-20120219.ebuild
new file mode 100644
index 000000000000..8d94d49a2bf3
--- /dev/null
+++ b/sys-kernel/linux-firmware/linux-firmware-20120219.ebuild
@@ -0,0 +1,98 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/sys-kernel/linux-firmware/linux-firmware-20120219.ebuild,v 1.1 2012/02/21 21:41:45 chithanh Exp $
+
+EAPI=4
+inherit savedconfig
+
+if [[ ${PV} == 99999999* ]]; then
+	inherit git-2
+	SRC_URI=""
+	EGIT_REPO_URI="git://git.kernel.org/pub/scm/linux/kernel/git/firmware/${PN}.git"
+else
+	SRC_URI="mirror://gentoo/${P}.tar.gz"
+fi
+
+DESCRIPTION="Linux firmware files"
+HOMEPAGE="http://git.kernel.org/?p=linux/kernel/git/firmware/linux-firmware.git"
+
+LICENSE="GPL-1 GPL-2 GPL-3 BSD freedist"
+KEYWORDS="~amd64 ~arm ~x86"
+SLOT="0"
+IUSE="savedconfig"
+
+DEPEND=""
+RDEPEND="!savedconfig? (
+		!media-sound/alsa-firmware[alsa_cards_korg1212]
+		!media-sound/alsa-firmware[alsa_cards_maestro3]
+		!media-sound/alsa-firmware[alsa_cards_sb16]
+		!media-sound/alsa-firmware[alsa_cards_ymfpci]
+		!media-tv/cx18-firmware
+		!media-tv/ivtv-firmware
+		!media-tv/linuxtv-dvb-firmware[dvb_cards_cx231xx]
+		!media-tv/linuxtv-dvb-firmware[dvb_cards_cx23885]
+		!media-tv/linuxtv-dvb-firmware[dvb_cards_usb-dib0700]
+		!net-dialup/ueagle-atm
+		!net-dialup/ueagle4-atm
+		!net-wireless/ar9271-firmware
+		!net-wireless/i2400m-fw
+		!net-wireless/iwl1000-ucode
+		!net-wireless/iwl3945-ucode
+		!net-wireless/iwl4965-ucode
+		!net-wireless/iwl5000-ucode
+		!net-wireless/iwl5150-ucode
+		!net-wireless/iwl6000-ucode
+		!net-wireless/iwl6005-ucode
+		!net-wireless/iwl6030-ucode
+		!net-wireless/iwl6050-ucode
+		!net-wireless/libertas-firmware
+		!net-wireless/rt61-firmware
+		!net-wireless/rt73-firmware
+		!sys-block/qla-fc-firmware
+		!x11-drivers/radeon-ucode
+	)"
+#add anything else that collides to this
+
+src_unpack() {
+	if [[ ${PV} == 99999999* ]]; then
+		git-2_src_unpack
+	else
+		default
+		# rename directory from git snapshot tarball
+		mv ${PN}-*/ ${P} || die
+	fi
+}
+
+src_prepare() {
+	echo "# Remove files that shall not be installed from this list." > ${PN}.conf
+	find * \( \! -type d -and \! -name ${PN}.conf \) >> ${PN}.conf
+
+	if use savedconfig; then
+		restore_config ${PN}.conf
+		ebegin "Removing all files not listed in config"
+		find * \( \! -type d -and \! -name ${PN}.conf \) \
+			| sort ${PN}.conf ${PN}.conf - \
+			| uniq -u | xargs -r rm
+		eend $? || die
+		# remove empty directories, bug #396073
+		find -type d -empty -delete || die
+	fi
+}
+
+src_install() {
+	save_config ${PN}.conf
+	rm ${PN}.conf || die
+	insinto /lib/firmware/
+	doins -r *
+}
+
+pkg_preinst() {
+	if use savedconfig; then
+		ewarn "USE=savedconfig is active. You must handle file collisions manually."
+	fi
+}
+
+pkg_postinst() {
+	elog "If you are only interested in particular firmware files, edit the saved"
+	elog "configfile and remove those that you do not want."
+}