Version bump.

(Portage version: 2.2.0_alpha101/cvs/Linux x86_64)

3 files changed, 95 insertions, 3 deletions

diff --git a/dev-vcs/tortoisehg/ChangeLog b/dev-vcs/tortoisehg/ChangeLog
index 251dea1db363..9e771b99f309 100644
--- a/dev-vcs/tortoisehg/ChangeLog
+++ b/dev-vcs/tortoisehg/ChangeLog
@@ -1,6 +1,12 @@
 # ChangeLog for dev-vcs/tortoisehg
 # Copyright 1999-2012 Gentoo Foundation; Distributed under the GPL v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v 1.16 2012/05/03 02:25:52 floppym Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/ChangeLog,v 1.17 2012/05/07 18:04:45 floppym Exp $
+
+*tortoisehg-2.4 (07 May 2012)
+
+  07 May 2012; Mike Gilbert <floppym@gentoo.org> +tortoisehg-2.4.ebuild,
+  tortoisehg-9999.ebuild:
+  Version bump.
 
   03 May 2012; Mike Gilbert <floppym@gentoo.org> -tortoisehg-2.3.ebuild,
   tortoisehg-2.3.1.ebuild:
diff --git a/dev-vcs/tortoisehg/tortoisehg-2.4.ebuild b/dev-vcs/tortoisehg/tortoisehg-2.4.ebuild
new file mode 100644
index 000000000000..5b243caa7b6e
--- /dev/null
+++ b/dev-vcs/tortoisehg/tortoisehg-2.4.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2012 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-2.4.ebuild,v 1.1 2012/05/07 18:04:45 floppym Exp $
+
+EAPI=4
+
+SUPPORT_PYTHON_ABIS=1
+PYTHON_DEPEND="2:2.5"
+RESTRICT_PYTHON_ABIS="2.4 3.* *-pypy-*"
+
+inherit distutils eutils multilib
+
+if [[ ${PV} != *9999* ]]; then
+	KEYWORDS="~amd64 ~x86"
+	SRC_URI="mirror://bitbucket/${PN}/targz/downloads/${P}.tar.gz"
+else
+	inherit mercurial
+	EHG_REPO_URI="https://bitbucket.org/tortoisehg/thg"
+	KEYWORDS=""
+	SRC_URI=""
+fi
+
+DESCRIPTION="Set of graphical tools for Mercurial"
+HOMEPAGE="http://tortoisehg.bitbucket.org"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="doc nautilus"
+
+RDEPEND="dev-python/iniparse
+	dev-python/pygments
+	dev-python/PyQt4
+	dev-python/qscintilla-python
+	>=dev-vcs/mercurial-2.1
+	<dev-vcs/mercurial-2.3
+	nautilus? ( dev-python/nautilus-python )"
+DEPEND="${RDEPEND}
+	doc? ( >=dev-python/sphinx-1.0.3 )"
+
+src_prepare() {
+	# make the install respect multilib.
+	sed -i -e "s:lib/nautilus:$(get_libdir)/nautilus:" setup.py || die
+
+	if [[ ${LINGUAS+set} ]]; then
+		pushd i18n/tortoisehg > /dev/null || die
+		local x y keep
+		for x in *.po; do
+			keep=
+			for y in ${LINGUAS}; do
+				if [[ ${y} == ${x%.po}* ]]; then
+					keep=1
+					break
+				fi
+			done
+			[[ ${keep} ]] || rm "${x}" || die
+		done
+		popd > /dev/null || die
+	fi
+
+	distutils_src_prepare
+}
+
+src_compile() {
+	distutils_src_compile
+
+	if use doc ; then
+		emake -C doc html
+	fi
+}
+
+src_install() {
+	distutils_src_install
+	dodoc doc/ReadMe*.txt doc/TODO
+
+	if use doc ; then
+		dohtml -r doc/build/html || die
+	fi
+
+	insinto /usr/share/icons/hicolor/scalable/apps
+	newins icons/scalable/apps/thg-logo.svg tortoisehg_logo.svg
+	domenu contrib/${PN}.desktop
+
+	if ! use nautilus; then
+		rm -r "${ED}usr/$(get_libdir)/nautilus" || die
+	fi
+}
diff --git a/dev-vcs/tortoisehg/tortoisehg-9999.ebuild b/dev-vcs/tortoisehg/tortoisehg-9999.ebuild
index e1a2630f4abf..c52687fcadff 100644
--- a/dev-vcs/tortoisehg/tortoisehg-9999.ebuild
+++ b/dev-vcs/tortoisehg/tortoisehg-9999.ebuild
@@ -1,6 +1,6 @@
 # Copyright 1999-2012 Gentoo Foundation
 # Distributed under the terms of the GNU General Public License v2
-# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-9999.ebuild,v 1.6 2012/04/17 15:04:36 mgorny Exp $
+# $Header: /var/cvsroot/gentoo-x86/dev-vcs/tortoisehg/tortoisehg-9999.ebuild,v 1.7 2012/05/07 18:04:45 floppym Exp $
 
 EAPI=4
 
@@ -31,7 +31,7 @@ RDEPEND="dev-python/iniparse
 	dev-python/pygments
 	dev-python/PyQt4
 	dev-python/qscintilla-python
-	>=dev-vcs/mercurial-2.0
+	dev-vcs/mercurial
 	nautilus? ( dev-python/nautilus-python )"
 DEPEND="${RDEPEND}
 	doc? ( >=dev-python/sphinx-1.0.3 )"